SR5 Tactical IED Detection and Remote Det Script

[Reezo 45]

1. I already have (in my mind) your trigger script working with ambient civilians at least on Takistan. Being that its trigger based with civilians present, this trigger only becoming true when civilians are generated by ALICE2 as players approach. Ambient vehicles is still a little dummer but provides cars for the car bombs.

You don't need to use the trigger method with my script (triggerman_spawn.sqf) in the next version you will be able to add a line to the init.sqf and run a script (ambientBombers.sqf) that will attach and run only to group leaders of a specific side (dynamically changing if the leader changes). This script works in conjuction to the leader presence, not the civilians. This means it works with ALICE and non-ALICE civilians (e.g. editor-placed). You can set a % of bombermen presence and the minimum amount of civilians to run for. You can set a pause interval time between checks but the script is already highly optimized: it pauses if the leader stays in the same area or if a triggerman was found and the leader stays in his town. If a leader moves away from the triggerman town, the script restarts normally. It is a very nice piece of script that could easily become an in-editor module "Ambient Bombers".

2. I am looking at various bits of "furniture" such as market stalls. garbage bins etc to run as additional IED object possibilities, replacing the "car" class type in the trigger. Be even nicer if that could be made random, but my scripting knowledge ends at the mission writing stage. I guess a random IED object generator within the trigger action would do the trick, spawn the random item, attach IED, generate trigger man. Is this in the realms of possibility ?

I think if you put "any" you will have total random class usage :)

3. I would like to test your pressure plate IED script but I am not sure on how to set it. Via Trigger or item init ? It would be nice to again make this random, either by position or item. Makes missions so much more repeatable.

Via object init. it uses three parameters: [this,0,0], this being the item, 0 the beep (0,1,2) and 0 being the pressure type (0=anti-personnel, 1=anti-vehicle). The randomization factor could be in the object properties: placement radius and probability of presence? This should answer ckolonko's as well :)

4. Nice to see the suicide bombers doing random actions, nice touch.

Yeah, we got some nice 50cal moments during some town patrols, all of a sudden from the town market area a woman starts running towards the HMMWV..sometimes they scream before running, sometimes after, so this makes it harder to understand. Btw the woman was running from something else, the gunner didn't let her come close anyway..cruelty of war.

5. Electronic counter measures. Be nice to have a bomb jammer instead of a detector, more realistic. This should be able to jam long range remote detonated bombs, but obviously not the pressure plated items. This should really be for wireless remote detonated devices, where you can put the trigger man up on a hill with a set of binos and a radio trigger. I have this observation routine working on OPFOR artillery observers, should be able to make long range triggermen like this. The nice ballancer is if people stay in a vehicles protective EW bubble they would be safe.

It could be done, in the future I might start to look into what is realistically used even if at prototype-stage, to add different kind of detectors. What I'd love is to have the Nomad as a real item, running the script if you have it on you.

6. More ideas to come, awesome script, its adding nice polishing touches to my soon to be public beta mission, that you will love. Its going to be as real as I can get.

Awesome! I'll upload it into SR5 server and we'll definitely play it! Word :) Edited March 18, 2011 by Reezo

[ckolonko 0]

Cheers, Reezo. Got it working. Love how the IED beeps three times before detonation! You have certainly made an excellent script. I also like how the two IED types can be set off by only infantry or a vehicle. Is there any chance of a third option for an IED that can be set off by both? And also would it be possible to have a random charge, e.g anything from 30mm-GBU as well as making the bomb less likely to detonate if you move towards it slowly to disarm it?

Edited March 18, 2011 by ckolonko

[Reezo 45]

Cheers, Reezo. Got it working. Love how the IED beeps three times before detonation!

;) eheh yeah

[Reezo 45]

From the upcoming readme.txt

4g) You can also use what I called the "Ambient Bombers" script. To do so, write this in your init.sqf file:

nul0 = [200,4,50,10,"car",0,55,30,25,WEST] execVM "scripts\IEDdetect\IEDdetect_ambientBombers.sqf";

Where:

200 - is the ambient radius from the player

4 - is the minimum amount of civilians near the player

50 - is the % of presence of a triggerman among them

10 - is the scan interval time

"car" - is the object classtype of what could potentially host triggermen bombs (there is always a 50% chance it will be a suicide bomber)

0 - is the beeping (0=no beep, 1=beep, 2=random)

55 - is the area to scan for suitable objects (e.g. "car") and attach the bomb to one of those, randomly. This is also the scan area for the triggerman to trigger the bomb

30 - is the area to scan for hostiles that can instill fear in the triggerman (read above for how fear works).

25 - is the area to scan for possible victims that will make the triggerman touch the bomb off.

WEST - is the side to consider enemy of the triggerman

This script works by attaching itself to group leaders of the enemy faction ONLY (WEST in the example). This means it will work as a sort of Ambient Combat Module (ACM), following group leaders and "making things happen around them". The script checks for civilian presence in a pre-determined "ambient radius" (200m in the example) around the player. If a minimum number of civilians (4 in the example) is found, it will try the % of presence (50 in the example) for a triggerman to be among them. If positive, it will turn one of the civilians into a triggerman and decide whether it is a suicide bomber or a remote-detonator. In case it is the latter, it will scan for a specific object class ("car" in the example) in a pre-determined radius from the triggerman (55 in the example) and attach a bomb to it. After that the triggerman will behave just like illustrated in the previous paragraph. The script pauses itself for the interval specified by the user (10 in the example) if the player stays around the same area or around the same triggerman. The script attaches itself to new leaders in case a group leader changes. This script works well with ALICE-created and user-created civilians. It also moves with the player so it is very easy to use and is totally automated.

[kremator 1065]

Great stuff!

[Reezo 45]

I am going to post the pre-release here, without making a big announcement. You guys test it and let me know, if everything works I will release it in the main page as well. After all, all we need to try out is the ambient Bombers part, which worked for me very well, because the pressure plate script is as easy as you can say BOOM.

One thing I've forgot to mention is that IEDs created with this script are sensible to damage. This makes it possible for an EOD to use anti material rifles to detonate the IED safely from a distance if the situation allows it. As some of you know, EOD soldiers have a fairly good knowledge of precision rifles such as the M107 because they get trained to use it on the field for the purpose of detonating ordnance from afar.

If this is wrong info, please correct me. Some may have seen something related to this in the movie "The Hurt Locker" where fans complained the m107 scene was unrealistic. The director replied it was not since the confidence in using the rifle comes from this ordnance disposal training which also involves long range shooting.

Edited March 19, 2011 by Reezo

[kremator 1065]

Sounds like a good idea Reezo.

/me is ready to test :)

[Reezo 45]

Here is the test version of v1.6:

http://www.mediafire.com/?0ucsu194bl0t7c1

happy testing :)

[Kolmain 6]

Is there anyway to add an IED weapon or something that can be detectable on the unit using ACE2? Thinking you should be able to search people for it, maybe make the triggerman stay 10m from west units if not suicide?

[Reezo 45]

It could be done but I need documentation on ACE2 search/disarm function, until now I haven't found much and it seems to produce no results when used on civilians.

For 10m just use 10 as detArea

[ckolonko 0]

Is there anyway to make the Display show up on 4:3 aspect screens at all?

[Reezo 45]

Is there anyway to make the Display show up on 4:3 aspect screens at all?

I fear the only solution will be to move the display center-bottom and right-bottom. I could move it slightly to the center but At that point centered could be better.

It is weird because I used relative screen positions, it should be in the corner for all screen formats..anyone has a clue about it? Maybe it is an A2 glitch?

X - the offset from the left side of the window (0..1; 0.0 = left side; 1.0 = right side)

Y - float the offset from the top side of the window (0..1; 0.0 = left side; 1.0 = right side)

[ckolonko 0]

That's be fine as long as I can see the display.

[spectrersg 9]

Reez, there's 9 of us doing this at this moment.

We came across two incidents:

1) When two bombs are within detection range, the detectors spazzes out rendering it useless. It constantly detects one after another and never places a waypoint on the map because of it's infinite loop of detections.

2) As we were flying into the IED Course, an IED randomly got attached to our chopper... Can you exclude occupied objects from being able to have an ied attached when the triggerman is searching for a location? (Btw, Lol).

[Reezo 45]

Lol nice! Did you use ANY?

I will make sure the Air class is checked against the possibilities lol!

And the spazzing out is weird..baad bug. :)

Thanks!

[spectrersg 9]

Well, I'm just scared that it may happen again, when we're on patrol in our M1151's. Is there a way to have it check for any WEST occupied vehicle?

Edit: the chopper was a Venom, if it matters.

Edited March 20, 2011 by SpectreRSG

[Reezo 45]

Sure I can add more checks, that is a great find (but a fun one to FRAP) lol

Tell me please: if a vehicle has WEST people in it, it becomes WEST, right?

UPDATE: Spectre, for the "IED detector going crazy" problem, try replace IEDdetect.sqf with this one:

//////////////////////////////////////////////////////////////////
// Function file for Armed Assault
// Created by: Reezo of SR5 Tactical - www.sr5tactical.net
// IED Detection and Disposal Scripts
//////////////////////////////////////////////////////////////////

// INIT
private ["_detector","_range","_interval","_skill","_fakeRatio","_near","_nearCount","_IEDmarker","_rnd","_posX","_posY","_sign","_y","_h","_iedMarkename","_createvarname","_numberMarker","_action_reezo_IEDdetect_remoteDet","_action_reezo_IEDdetect_manualDefuse","_lapse","_nearHosts","_thisHost","_action_reezo_IEDdetect_detach","_fakeIED"];

waitUntil {time > 5};

_detector = _this select 0;
_range = _this select 1;
_interval = _this select 2;
_skill = _this select 3;
_fakeRatio = _this select 4;
_fakeIED = 0;

if (!local _detector) exitWith {};
waitUntil {reezo_IEDdetect_initComplete};

// MAIN SCAN LOOP
while {alive _detector} do {
 if (reezo_IEDdetect_debug) then { player globalChat "NOW RUNNING: MAIN SCAN LOOP" };

 while {count reezo_IED_detector_objects == 0 OR reezo_IEDdetect_busy == 1} do { sleep (_interval * 2) };

 _near = (getPos _detector) nearObjects (_range - ((speed _detector) * 1.25));
 _nearCount = count _near;
 if (_nearCount > 50) then {_nearCount = 50};

 // CASE 1. FAKE IED DETECTED (radio interferences or whatever gizmo might trigger it)
 _rnd = random 100;  

 if (reezo_IEDdetect_busy == 0) then {
   if (_rnd < _fakeRatio && reezo_IEDdetect_busy == 0 && _nearCount > 5) then {
     if (reezo_IEDdetect_debug) then { player globalChat "NOW RUNNING: FAKE IED CODE" }; sleep 1;

     // Script goes busy
     reezo_IEDdetect_busy = 1;
     publicVariable "reezo_IEDdetect_busy";
     _fakeIED = 1;

     // ACQUIRE IED AND BROADCAST, adding it to the "Found IEDs" array
     reezo_IEDdetect_activeIED = _near select (floor (random _nearCount));
     publicVariable "reezo_IEDdetect_activeIED";
     reezo_IEDdetect_activeEOD = _detector;
     publicVariable "reezo_IEDdetect_activeEOD";

     // Scanner notification (Scanning..)
     waitUntil {!dialog}; cutRsc ["IEDdetect_01", "PLAIN", 0];
     playsound "IEDdetect_beep"; sleep 1;
     playsound "IEDdetect_beep"; sleep 1;
     playsound "IEDdetect_beep"; sleep 1;
     sleep 2;

     //MARKER PLACEMENT (approximate)
     deleteMarkerLocal "REEZOIED";
     deleteMarkerLocal _iedMarkename;
     sleep 0.1;    
     _rnd = random _range;
     _sign = random 1;
     if (_sign < 0.5) then { _rnd = -1 * _rnd };
     _posX = (getPos (_detector) select 0) + _rnd;
     _rnd = random _range;
     _sign = random 1;
     if (_sign < 0.5) then { _rnd = -1 * _rnd };
     _posY = (getPos (_detector) select 1) + _rnd;

     // GENERATE NAME NOT IN USE GLOBALLY
     _iedMarkename = "REEZOIED";
     _numberMarker = 0;
     if (isnil ("REEZOIED")) then {_iedMarkename="REEZOIED"} else {
       _createvarname = true;
       while {_createvarname} do {
         _iedMarkename = format["REEZOIED_%1",_numberMarker];
         if (isnil ("_iedMarkename")) then {
           _createvarname = false;
         } else {
           _numberMarker = _numberMarker+ 1;
         };
       };
     };
     _IEDmarker = createMarkerLocal[_iedMarkename,[_posX,_posY]];
     _IEDmarker setMarkerShape "ICON";
     _IEDmarker setMarkerType "WARNING";
     _IEDmarker setMarkerColor "colorRed";
     _IEDmarker setMarkerText "IED Approx. Position";
     _IEDmarker setMarkerSize [.50, .50];

     // Report the fake IED
     waitUntil {!dialog}; cutRsc ["IEDdetect_02", "PLAIN", 0];
     playsound "IEDdetect_beep2";
     sleep 15 + floor (random 90);

     // After some time..declare the IED fake
     waitUntil {!dialog}; cutRsc ["IEDdetect_07", "PLAIN", 0];
     playsound "IEDdetect_beep2";

     // Cleaning
     deleteMarkerLocal "REEZOIED";
     deleteMarkerLocal _iedMarkename;
   };

   if (_fakeIED == 0) then {
     for [{_y = 0},{_y < _nearCount},{_y = _y + 1}] do {

       // CASE 2. REAL IED DETECTED
         if ((_near select _y) in reezo_IED_detector_objects) then {
           if (reezo_IEDdetect_debug) then { player globalChat "NOW RUNNING: REAL IED CODE" }; sleep 1;

           // Script goes busy
           reezo_IEDdetect_busy = 1;
           publicVariable "reezo_IEDdetect_busy";

           // ACQUIRE IED AND BROADCAST, adding it to the "Found IEDs" array
           reezo_IEDdetect_activeIED = _near select _y;
           publicVariable "reezo_IEDdetect_activeIED";
           reezo_IEDdetect_activeEOD = _detector;
           publicVariable "reezo_IEDdetect_activeEOD";

               if (reezo_IEDdetect_debug) then {
                 hint Format["Array:\n\n%1\n\nActiveIED:\n\n%2\n\nActiveEOD:\n\n%3",reezo_IED_detector_objects,reezo_IEDdetect_activeIED, reezo_IEDdetect_activeEOD];
                 sleep 1;
               };

           // Scanner notification (Scanning..)
           waitUntil {!dialog}; cutRsc ["IEDdetect_01", "PLAIN", 0];
           playsound "IEDdetect_beep"; sleep 1;
           playsound "IEDdetect_beep"; sleep 1;
           playsound "IEDdetect_beep"; sleep 1;
           sleep 2;

           //MARKER PLACEMENT (approximate)
           deleteMarkerLocal "REEZOIED";
           deleteMarkerLocal _iedMarkename;
           sleep 0.1;    
           _rnd = random 5;
           _sign = random 1;
           if (_sign < 0.5) then { _rnd = -1 * _rnd };
           _posX = (getPos (reezo_IEDdetect_activeIED) select 0) + _rnd;
           _rnd = random 5;
           _sign = random 1;
           if (_sign < 0.5) then { _rnd = -1 * _rnd };
           _posY = (getPos (reezo_IEDdetect_activeIED) select 1) + _rnd;

           // GENERATE NAME NOT IN USE GLOBALLY
           _iedMarkename = "REEZOIED";
           _numberMarker = 0;
           if (isnil ("REEZOIED")) then {_iedMarkename="REEZOIED"} else {
             _createvarname = true;
             while {_createvarname} do {
               _iedMarkename = format["REEZOIED_%1",_numberMarker];
               if (isnil ("_iedMarkename")) then {
                 _createvarname = false;
               } else {
                 _numberMarker = _numberMarker+ 1;
               };
             };
           };
           _IEDmarker = createMarkerLocal[_iedMarkename,[_posX,_posY]];
           _IEDmarker setMarkerShape "ICON";
           _IEDmarker setMarkerType "WARNING";
           _IEDmarker setMarkerColor "colorRed";
           _IEDmarker setMarkerText "IED Approx. Position";
           _IEDmarker setMarkerSize [.50, .50];

           // Notify the IED found, add disarm actions     
           waitUntil {!dialog}; cutRsc ["IEDdetect_02", "PLAIN", 0];
           playsound "IEDdetect_beep2";
           reezo_IEDdetect_activeIED removeAction _action_reezo_IEDdetect_manualDefuse;
           _action_reezo_IEDdetect_manualDefuse = reezo_IEDdetect_activeIED addAction ['<t color="#FF9800">'+"Defuse Bomb"+'</t>', "scripts\IEDdetect\IEDdetect_manualDefuse.sqf", [], 0, false, true, "",""];

           //check if IED is attached to something and if it is, place a Detach action on it
           if (reezo_IEDdetect_activeIED in reezo_IEDdetect_attachedIEDs) then {
             _nearHosts = ((getPos reezo_IEDdetect_activeIED) nearObjects 3) - [reezo_IEDdetect_activeIED];
             for [{_h= 0},{_h < (count _nearhosts)},{_h = _h + 1}] do {
               _thisHost = _nearHosts select _h;
               if (_thisHost in reezo_IEDdetect_hostIEDs) then {
                 _action_reezo_IEDdetect_detach = _thisHost addAction ['<t color="#FF3300">'+"Detach IED"+'</t>', "scripts\IEDdetect\IEDdetect_detach.sqf", [reezo_IEDdetect_activeIED], 0, false, true, "",""];
               };
             };
           };

           // Remote Det possibility
           _rnd = random 100;
           if (_rnd < _skill) then {
             sleep 4;
             waitUntil {!dialog}; cutRsc ["IEDdetect_03", "PLAIN", 0];
             playsound "IEDdetect_beep2";
             reezo_IEDdetect_activeEOD removeAction _action_reezo_IEDdetect_remoteDet;
             _action_reezo_IEDdetect_remoteDet = reezo_IEDdetect_activeEOD addAction ['<t color="#FF9800">'+"Remotely Detonate Bomb"+'</t>', "scripts\IEDdetect\IEDdetect_remoteDet.sqf", [reezo_IEDdetect_activeIED], 0, false, true, "",""];
           };

         }; // END IF

       // MAIN WAIT LOOP
       _lapse = 1;
       while { reezo_IEDdetect_busy == 1 && _lapse < 36 && alive reezo_IEDdetect_activeIED && alive reezo_IEDdetect_activeEOD && reezo_IEDdetect_activeIED distance reezo_IEDdetect_activeEOD < 300} do {
         // update IED marker if it moved in the meantime
         if (speed reezo_IEDdetect_activeIED != 0) then {
           _rnd = random 5;
           _sign = random 1;
           if (_sign < 0.5) then { _rnd = -1 * _rnd };
           _posX = (getPos (reezo_IEDdetect_activeIED) select 0) + _rnd;
           _rnd = random 5;
           _sign = random 1;
           if (_sign < 0.5) then { _rnd = -1 * _rnd };
           _posY = (getPos (reezo_IEDdetect_activeIED) select 1) + _rnd;
           _iedMarkename setMarkerPos [_posX, _posY];
         };

         sleep 5;
         _lapse = _lapse + 1;
       };

       reezo_IEDdetect_activeEOD removeAction _action_reezo_IEDdetect_remoteDet;

       deleteMarkerLocal "REEZOIED";
       deleteMarkerLocal _iedMarkename;

       //reezo_IEDdetect_activeIED = _detector;
       //publicVariable "reezo_IEDdetect_activeIED";
       //reezo_IEDdetect_activeEOD = _detector;
       //publicVariable "reezo_IEDdetect_activeEOD";
     }; // END FOR
   }; //END IF FAKEIED == 0
 }; // END IF IEDDETECT_BUSY == 0

 reezo_IEDdetect_busy = 0;
 publicVariable "reezo_IEDdetect_busy";
 sleep _interval;

}; // END WHILE

if (reezo_IEDdetect_debug) then { player globalChat "reezo_IEDDETECT DEBUG: IEDDETECT.SQF COMPLETE" };

if (true) exitWith {};

Edited March 20, 2011 by Reezo

[spectrersg 9]

I'll put it in, and get back to you if it happens again.

Tell me please: if a vehicle has WEST people in it, it becomes WEST, right?

Not a clue. Sorry.

[Reezo 45]

No problem.

If you want to get the whole updated suite guys, get it here:

http://www.sr5tactical.net/reezo_ieddetect_v16rc.7z

this is still unreleased officially but, there :)

[spectrersg 9]

Just to make sure, that download consisted of the file you wanted me to change, right?

Edit: also, 4a on your first page says to turn a vehicle into a detector as well. Did you tell me a few days ago that I couldn't make an empty vehicle a detector?

Edited March 20, 2011 by SpectreRSG

[UGLY58 10]

I was looking for suitable items to turn into IEDS. I got a bit carried away, but if you are looking for an item to attach IEDs to, here is a list of class names of items I think are suitable.

I stopped short on every type of magazine or military junk that gets dropped then consequently IED`d.

"Oh look there is a spare mangazine I`ll have that"...BOOM...smoking boots remain......you get the idea.

If anyone can turn this into a random selection list, with some kind reasonable positioning script. It would make Reezos proximity IED script a little more random, other than just random placing and chance.

I think Bon has something along the positioning lines in his TFOR IED script.

Land_Ind_TankSmall2_EP1

Land_Market_shelter_EP1

Land_Market_stalls_01_EP1

Land_Market_stalls_02_EP1

Land_covering_hut_EP1

Land_covering_hut_big_EP1

Fort_Barricade_EP1

Fort_StoneWall_EP1

Land_Bench_EP1

Land_Carpet_2_EP1

Dirtmount_EP1

Land_Carpet_rack_EP1

Land_Crates_EP1

Land_Crates_stack_EP1

Land_Dirthump01_EP1

Land_Dirthump02_EP1

Land_Dirthump03_EP1

Land_Misc_Coil_EP1

Land_Misc_ConcBox_EP1

Land_Misc_ConcOutlet_EP1

Land_Misc_ConcPipeline_EP1

Land_Misc_Garb_Heap_EP1

Land_Misc_IronPipes_EP1

Land_Misc_Rubble_EP1

Land_Misc_Well_C_EP1

Land_Misc_Well_L_EP1

Land_bags_EP1

Land_bags_stack_EP1

Land_cages_EP1

Land_stand_meat_EP1

Land_stand_small_EP1

Land_transport_cart_EP1

Land_transport_crates_EP1

Land_transport_kiosk_EP1

UNBasicAmmunitionBox_EP1

UNBasicWeapons_EP1

FlagPole_EP1

UH60_wreck_EP1

Sign_1L_Firstaid_EP1

Sign_1L_Noentry_EP1

GraveCross2_EP1

GraveCrossHelmet_EP1

Hedgehog_EP1

Infostand_1_EP1

Infostand_2_EP1

Land_Bag_EP1

Land_Basket_EP1

Land_Blankets_EP1

Land_Boots_EP1

Land_Bowl_EP1

Land_Bucket_EP1

Land_Canister_EP1

Land_Pillow_EP1

Land_Rack_EP1

Land_Reservoir_EP1

Land_Sack_EP1

Land_Shelf_EP1

Land_Table_EP1

Land_Table_small_EP1

Land_Teapot_EP1

Land_Urn_EP1

Land_Vase_EP1

Land_Vase_loam_2_EP1

Land_Vase_loam_3_EP1

Land_Vase_loam_EP1

Land_Water_pipe_EP1

Land_Wheel_cart_EP1

Land_Wicker_basket_EP1

Land_stand_waterl_EP1

Land_sunshade_EP1

30Rnd_545x39_AK

BAF_ied_v1

BAF_ied_v2

BAF_ied_v3

BAF_ied_v4

PMC_ied_v1

PMC_ied_v2

PMC_ied_v3

PMC_ied_v4

Land_BoatSmall_1

Land_BoatSmall_2a

Land_BoatSmall_2b

Land_Ind_Timbers

Land_KBud

Land_Shed_M01

Land_Shed_M02

Land_Shed_M03

Land_Shed_W01

Land_Shed_W02

Land_Shed_W03

Land_Shed_W4

Land_Vez_Pec

Land_Wall_CBrk_5_D

Land_Wall_CGry_5_D

Land_hut06

Land_psi_bouda

Land_pumpa

Land_ruin_01

Land_ruin_chimney

Land_ruin_corner_1

Land_ruin_corner_2

Land_ruin_rubble

Land_ruin_wall

Land_ruin_walldoo

Body

Grave

GraveCross1

GraveCross2

GraveCrossHelmet

Hanged

Hanged_MD

Land_Church_tomb_1

Land_Church_tomb_2

Land_Church_tomb_3

Mass_grave

Fort_Barricade

Fort_Crate_wood

Desk

FoldChair

FoldTable

Park_bench1

Park_bench2

Park_bench2_noRoad

SmallTable

WoodChair

Axe_woodblock

Barrel1

Barrel4

Barrel5

Haystack_small

Land_Barrel_empty

Land_Barrel_sand

Land_Barrel_water

BMP2Wreck

BRDMWreck

HMMWVWreck

LADAWreck

Mi8Wreck

SKODAWreck

T72Wreck

T72WreckTurret

UAZWreck

UH1Wreck

UralWreck

datsun01Wreck

datsun02Wreck

hiluxWreck

Baseball

Can_small

EvDogTags

EvKobalt

EvMap

EvMoney

EvMoscow

EvPhoto

Explosive

FloorMop

Loudspeaker

MetalBucket

Misc_Videoprojektor

Misc_Videoprojektor_platno

Misc_Wall_lamp

Notebook

Radio

SatPhone

SkeetDisk

SkeetMachine

SmallTV

Suitcase

bomb

[Reezo 45]

@Spectre, that download (.7z) is the entire new version of the script suite, it has a couple fixes here and there about the "attaching IEDs to choppers and other funny but wrong things".

@Ugly, I think I will use that list and default to it. I think pretty much everyone prefers it for randomized stuff rather than "car" or other more restrictive classes. I mean, if it's not a suicide bomber, that randomized list is going to work great.

Stay tuned, I need to sleep :)

[spectrersg 9]

Well when ya wake up, dont forgot about my edit. ;)

Edit: also, 4a on your first page says to turn a vehicle into a detector as well. Did you tell me a few days ago that I couldn't make an empty vehicle a detector?

[Reezo 45]

Eheh :)

Well, I am not sure the detect script - as it is now - will work on vehicles. I must remember to remove that 4a..I could create a specific script to make it work on vehicles..that's for sure :)

[UGLY58 10]

Reezo,

Make a handheld detector, but a Vehicle Jammer,

If vehicle with jammer is within 50 meters of an remote ied, then remote ied with a triggerman over 10om away will not explode.

...if only scripting was that easy..

I know, another script, but would be a nice addition