Couple of Scripts for anyone that want's them

ColonelSandersLite · March 10, 2006

With ofpec down, I thought I might post these for anyone who may have problems with vehicle embarking/disembarking involving a player and WP synchronisation.

Most of the experienced editors will probably have written their own versions already (or gotten one off of ofpec). Still, I thought I'd post these for anyone who's not very experienced, or just doesn't have something similar.

Anyways, Looking through these forums, this seems like it's actually one of the few worthwhile communities on the internet. There's no real trolling or flaming to speak of, and this community seems to be full of helpfull people. So, I think I'll start taking an active part.

I'll be posting assorted scripts that I write, and maybe start putting out missions for the public if you guys would give me some good leads on where they should be hosted.

Anyways, without further ado, here's the promissed scripts.

<table border="0" align="center" width="95%" cellpadding="0" cellspacing="0"><tr><td>Code Sample </td></tr><tr><td id="CODE">; Vehicle Unload by ColonelSandersLite Version 1.0

; Requirements:

;

; The Transporting vehicle is assumed to be a truck/apc/whatever, but helicopters wont work

; The squad needs to have a group name. This can be acheived by putting the following in the

; init feild of the squad leader: myGroupName = group this;

; The Transporting vehicle must have a name

; The squad must be in the vehicle before getting out of the vehicle;)

; Usage (who controls the squad doesn't matter at all):

;

; make a move waypoint (NOT A TRANSPORT UNLOAD) for your vehicle where you want

; the squad to disembark from and put the following in the on activation box.

;

; [myVehicleName, (leader MyGroupName), delayInSeconds] exec "vehunload.sqs"

; Example : [testVeh1, (leader testGroup1), 20] exec "vehunload.sqs"

;

; DelayInSeconds is the time the truck will wait to leave after everyone is out.

; Reccomended value is 15-30 seconds, but testing is reccomended. This is here, so the

; squad is clear of the vehicle before it drives off, in order to prevent

; ai driver wonkieness. It can be set to 0 if you don't care to have it.

;

; The squad does not need a get out waypoint, just a normal waypoint to their destination

; after the truck has unloaded them.

; BEGIN SCRIPT

; Get All Passed Data.

_veh = _this select 0

_leader = _this select 1

_delay = _this select 2

; initialize variables.

_stopped = false

_squad = units group _leader

; Stop the vehicle from trying to go to the next WP.

_veh LockWP true

; Stop the vehicle.

_veh action ["Engine Off"]

; This loop checks that the vehicle is stopped and wont let the script progress till it does.

#stoppedCheckLoop

? (velocity _veh select 0 == 0) AND (velocity _veh select 1 == 0) AND (velocity _veh select 2 == 0) : _stopped = true

~1

? !_stopped : goto "stoppedCheckLoop"

; This unloads everyone, even players, quickly.

; reset getOutLoop counter

_tmp = 0

; count the living squad mates

_num = "alive _x" count _squad

#getOutLoop

? (((_squad select _tmp) in _veh) AND (alive (_squad select _tmp))) : unassignVehicle (_squad select _tmp); (_squad select _tmp) action ["eject", _veh]

~.85

_tmp = _tmp + 1

? _tmp < _num : goto "getOutLoop"

; make double sure that everyone is out by runngin the getOutLoop Again without the delay between members

; reset getOutLoop2 counter

_tmp = 0

; count the living squad mates

_num = "alive _x" count _squad

#getOutLoop2

? (((_squad select _tmp) in _veh) AND (alive (_squad select _tmp))) : unassignVehicle (_squad select _tmp); (_squad select _tmp) action ["eject", _veh]

_tmp = _tmp + 1

? _tmp < _num : goto "getOutLoop2"

; timer loop to make the vehicle wait the designated amount of time after squad disembarks.

_timewaited = 0

#waitLoop

~1

_timewaited = _timewaited + 1

? _timewaited < _delay : goto "waitLoop"

; Since everyone is out and clear, let the vehicle resume it's path.

_veh LockWP false

; finished

<table border="0" align="center" width="95%" cellpadding="0" cellspacing="0"><tr><td>Code Sample </td></tr><tr><td id="CODE">; Vehicle Pickup by ColonelSandersLite Version 1.0

; Requirements:

;

; The Transporting vehicle is assumed to be a truck/apc/whatever, but helicopters wont work

; The squad needs to have a group name. This can be acheived by putting the following in the

; init feild of the squad leader: myGroupName = group this;

; The Transporting vehicle must have a name

; Usage if the squad is DEFINATELY going to be PLAYER controlled:

;

; Make a move waypoint (NOT LOAD) for your vehicle where you want the vehicle to wait at and

; put the following in the on activation box:

; [myVehicleName, (leader MyGroupName)] exec "vehpickup.sqs"

;

; The vehicle will wait for the player's squad to board

; Usage if the squad may possibly be player controlled, such as in the event of casualties:

;

; Make a move waypoint (NOT LOAD) for your vehicle where you want the vehicle to wait at and

; put the following in the on activation box:

; [myVehicleName, (leader MyGroupName)] exec "vehpickup.sqs"

;

; Make a small radius (10X10) trigger where the vehicle moves to pick up the men.

; Group it to the vehicle with "vehicle present (once)" being the activation.

; The Condition Should be:

; (this AND ((velocity myVehicleName select 0 == 0) AND (velocity myVehicleName select 1 == 0) AND (velocity myVehicleName select 2 == 0))) OR (!canMove myVehicleName)

; The on activation should read: myVehicleNameIsHere = 1;

;

; Give the squad a move/seek and destroy/guard/whatever waypoint. This is what the

; squad is doing before the truck comes to pick them up.

; The condition box should read: myVehicleNameIsHere == 1;

; The on activation should read: ("_x assignAsCargo myVehicleName") forEach (units MyGroupName);

;

; Give the squad a Get In waypoint near where the vehicle is going to load the squad.

;

; Give the Vehicle a move/seek and destroy/guard/whatever waypoint for where it goes after

; the squad is aboard.

; Usage if there's no possible way for the squad to be player controlled:

;

; Don't use this script, although it WILL WORK.

; It's simpler to just use synched load and get in waypoints.

; If you insist, follow the instructions for a squad may possibly be player controlled

; BEGIN SCRIPT

; Get All Passed Data.

_veh = _this select 0

_leader = _this select 1

; initialize variables.

_stopped = false

_squad = units group _leader

_squadGroup = group _leader

_veh LockWP true

_veh action ["Engine Off"]

; This loop checks that the vehicle is stopped and wont let the script progress till it does.

#stoppedCheckLoop

? (velocity _veh select 0 == 0) AND (velocity _veh select 1 == 0) AND (velocity _veh select 2 == 0) : _stopped = true

~1

? !_stopped : goto "stoppedCheckLoop"

; This loop keeps going until everyone is aboard

#waitForBoardLoop

; count the living squad mates

_num = "alive _x" count _squad

; reset counter for squad mates boarded

_inCount = 0

; reset testInLoop counter

_tmp = 0

; this loop counts the number of living squad mates in the vehicle and checks the whole squad

#testInLoop

? (((_squad select _tmp) in _veh) AND (alive (_squad select _tmp))) : _inCount = _inCount + 1

_tmp = _tmp + 1

? _tmp < (count _squad) : goto "testInLoop"

; small delay so the script doesn't eat too many resources

~1

; if all living squad members are not in the truck, loop

? _inCount != _num : goto "waitForBoardLoop"

; since everyone is aboard, let the truck move out

_veh LockWP false

; finished

2024-12-18T23:26:13Z

Thanks. Copied and pasted to scripts reference document.

ColonelSandersLite · March 10, 2006

BTW, feedback, bug reports, feature requests, script requests, etc, are ALWAYS welcome.

I'll also put together sample missions with examples on usage on request as well.

2024-12-18T23:26:13Z

Alright, ColonelSandersLite, now that you offered .....

A very helpfull script for myself and prolly for others too that I have been hoping to find in the near future would be:

A script that:

spawns a bmp in a particular spot, the bmp spawns completely loaded with units, driver, gunner, commander, and cargo is loaded with units as well.

Then script sends bmp to a location, unloads the troops, then moves to one last position.

This would show I would think everything one would need to do basic plans for spawning units, spawning units within vehicles in all vehicle positions, moving them thru script use and loading and unloading them - of course the loading and unloading you did put down, although it would be neat to see it mixed in a script like this.

This isnt a request or anything, if you feel like doin it.

Thanks for the offer, didnt take long to get a response eh? lol

funnyguy1 · July 1, 2004

I`m looking for a:

CAS script for helos (move in to player`s possition, make a mess (limited time) and fly away). Would this be possible to lase the targets for indirect strikes like in CoC arty? A helo targets the lased spot and fires missile, no matter where it`s pointed.

precision strike for a10 or other aircraft (realistic altitude and speed), for both mapclicked or lased targets.

evac script for helo that I could incorporate with GB`s handsignals

ressuplyscript where ammo creates are dropped from a helo, not spawned over the area

I want to make a mission with the GB`s handisgnals, so I need .sqs files that can be executed by this system. As you know you can`t use the ofp`s radio codes in order to call support.

I posted it here because i didn`t wanted to start a new thread about it, I`m a beginner so at least tell me what can be done from my whish list . I wish i could do it myself...

regards

ColonelSandersLite · March 10, 2006

Wow, ok, ok, slow down.

I'm rewriting my old heliload and helipickups at the moment.

I felt embarrassed about posting something so old that was based on someone elses work anyways.

They are actually already done but I need to test them out still.

I'll look over your script ideas and get on them once I'm done with these.

------------------------------------------------------

Ok the afformentioned Helicopter Scripts are finished and tested.

So:

<table border="0" align="center" width="95%" cellpadding="0" cellspacing="0"><tr><td>Code Sample </td></tr><tr><td id="CODE">; HeliDrop by ColonelSandersLite Version 2.0

; Requirements:

;

; The Transporting helicopter is assumed to be a helicopter

; The squad needs to have a group name. This can be acheived by putting the following in the

; init feild of the squad leader: myGroupName = group this;

; The Transporting helicopter must have a name

; The squad must be in the helicopter before getting out of the helicopter;)

; Usage (who controls the squad doesn't matter at all):

;

; Put a H or H(invisible) on the ground where the helicopter is supposed to land

;

; make a move waypoint (NOT A TRANSPORT UNLOAD) for your helicopter where you want

; the squad to disembark from and put the following in the on activation box.

;

; [myhelicopterName, (leader MyGroupName), DesiredFlyOutHeightInMeters] exec "helidrop2.sqs"

; Example : [testHeli1, (leader testGroup1), 50] exec "helidrop2.sqs"

;

; the distance between the move waypoint and H should be tweaked so the helicopter lands quickly and

; efficiently on normal time acc

;

; The squad does not need a get out waypoint, just a normal waypoint to their destination

; after the helicopter has unloaded them.

; BEGIN SCRIPT

; Get All Passed Data.

_heli = _this select 0

_leader = _this select 1

_flyOutHeight = _this select 2

; initialize variables.

_grounded = false

_landed = false

_squad = units group _leader

; Stop the helicopter from trying to go to the next WP.

_heli LockWP true

; Stop the helicopter.

_heli land "GET OUT"

; This loop waits until the helicopter is about to land (a couple of meters off the ground)

; then forces the to helicopter finish landing quickly and efficently,

#groundedCheckLoop

~0.5

? (GetPos _heli select 2) <= 2 : _heli flyinheight 0; _grounded = true

? !_grounded : goto "groundedCheckLoop"

; This loop checks that the helicopter is landed and wont let the script progress till it does.

#landedCheckLoop

~0.5

? (GetPos _heli select 2) <=.5 : _landed = true;

? !_landed : goto "landedCheckLoop"

; This unloads everyone, even players, quickly.

; reset getOutLoop counter

_tmp = 0

; count the living squad mates

_num = "alive _x" count _squad

#getOutLoop

? (((_squad select _tmp) in _heli) AND (alive (_squad select _tmp))) : unassignVehicle (_squad select _tmp); (_squad select _tmp) action ["eject", _heli]

~.85

_tmp = _tmp + 1

? _tmp < _num : goto "getOutLoop"

; make double sure that everyone is out by running the getOutLoop Again without the delay between members

; reset getOutLoop2 counter

_tmp = 0

; count the living squad mates

_num = "alive _x" count _squad

#getOutLoop2

? (((_squad select _tmp) in _heli) AND (alive (_squad select _tmp))) : unassignVehicle (_squad select _tmp); (_squad select _tmp) action ["eject", _heli]

_tmp = _tmp + 1

? _tmp < _num : goto "getOutLoop2"

; Since everyone is out and clear, let the helicopter resume it's path and set the flyInHeight as passed.

_heli LockWP false

_heli flyinheight _flyOutHeight

; finished

<table border="0" align="center" width="95%" cellpadding="0" cellspacing="0"><tr><td>Code Sample </td></tr><tr><td id="CODE">; HeliPickup by ColonelSandersLite Version 2.0

; Requirements:

;

; The Transporting helicopter is assumed to be a helicopter,

; The squad needs to have a group name. This can be acheived by putting the following in the

; init feild of the squad leader: myGroupName = group this;

; The Transporting helicopter must have a name

; Usage if the squad is DEFINATELY going to be PLAYER controlled:

;

; Put a H or H(invisible) on the ground where the helicopter is supposed to land

;

; Make a move waypoint (NOT LOAD) for your helicopter where you want the helicopter to wait at and

; put the following in the on activation box:

; [myhelicopterName, (leader MyGroupName), DesiredFlyOutHeightInMeters] exec "helipickup2.sqs"

;

; the distance between the move waypoint and H should be tweaked so the helicopter lands quickly and

; efficiently on normal time acc

;

; The helicopter will wait for the player's squad to board

; Usage if the squad may possibly be player controlled, such as in the event of casualties:

;

; Put a H or H(invisible) on the ground where the helicopter is supposed to land

;

; Make a move waypoint (NOT LOAD) for your helicopter where you want the helicopter to wait at and

; put the following in the on activation box:

; [myhelicopterName, (leader MyGroupName), DesiredFlyOutHeightInMeters] exec "helipickup2.sqs"

;

; the distance between the move waypoint and H should be tweaked so the helicopter lands quickly and

; efficiently on normal time acc

;

; Make a medium radius (100X100) trigger where the helicopter moves to pick up the men.

; Group it to the helicopter with "vehicle present (once)" being the activation.

; The Condition Should be:

; this OR (!canMove myhelicopterName)

; The on activation should read: myhelicopterNameIsHere = 1;

;

; Give the squad a move/seek and destroy/guard/whatever waypoint. This is what the

; squad is doing before the helicopter comes to pick them up.

; The condition box should read: myhelicopterNameIsHere == 1;

; The on activation should read: ("_x assignAsCargo myhelicopterName") forEach (units MyGroupName);

;

; Give the squad a Get In waypoint near where the helicopter is going to load the squad.

;

; Give the helicopter a move/seek and destroy/guard/whatever waypoint for where it goes after

; the squad is aboard.

; Usage if there's no possible way for the squad to be player controlled:

;

; Don't use this script, although it WILL WORK.

; It's simpler to just use synched load and get in waypoints.

; If you insist, follow the instructions for a squad may possibly be player controlled

; BEGIN SCRIPT

; Get All Passed Data.

_heli = _this select 0

_leader = _this select 1

_flyOutHeight = _this select 2

; initialize variables.

_grounded = false

_landed = false

_squad = units group _leader

; Stop the helicopter from trying to go to the next WP.

_heli LockWP true

; Stop the helicopter.

_heli land "GET OUT"

; This loop waits until the helicopter is about to land (a couple of meters off the ground)

; then forces the to helicopter finish landing quickly and efficently,

#groundedCheckLoop

~0.5

? (GetPos _heli select 2) <= 2 : _heli flyinheight 0; _grounded = true

? !_grounded : goto "groundedCheckLoop"

; This loop checks that the helicopter is landed and wont let the script progress till it does.

#landedCheckLoop

~0.5

? (GetPos _heli select 2) <=.5 : _landed = true;

? !_landed : goto "landedCheckLoop"

; This loop keeps going until everyone is aboard

#waitForBoardLoop

; count the living squad mates

_num = "alive _x" count _squad

; reset counter for squad mates boarded

_inCount = 0

; reset testInLoop counter

_tmp = 0

; this loop counts the number of living squad mates in the helicopter and checks the whole squad

#testInLoop

? (((_squad select _tmp) in _heli) AND (alive (_squad select _tmp))) : _inCount = _inCount + 1

_tmp = _tmp + 1

? _tmp < (count _squad) : goto "testInLoop"

; small delay so the script doesn't eat too many resources

~1

; if all living squad members are not in the helicopter, loop

? _inCount != _num : goto "waitForBoardLoop"

; Make double sure everyone is aboard

; This loop keeps going until everyone is aboard

#waitForBoardLoop2

; Wait a second to check again, also serves as a small delay so the script

; doesn't eat too many resources in the event the first check was inacurate

~1

; count the living squad mates

_num = "alive _x" count _squad

; reset counter for squad mates boarded

_inCount = 0

; reset testInLoop counter

_tmp = 0

; this loop counts the number of living squad mates in the helicopter and checks the whole squad

#testInLoop2

? (((_squad select _tmp) in _heli) AND (alive (_squad select _tmp))) : _inCount = _inCount + 1

_tmp = _tmp + 1

? _tmp < (count _squad) : goto "testInLoop2"

; if all living squad members are not in the helicopter, loop

? _inCount != _num : goto "waitForBoardLoop2"

; Since everyone is in, let the helicopter resume it's path and set the flyInHeight as passed.

_heli LockWP false

_heli flyinheight _flyOutHeight

; finished

Now to Start the requests. Special Ed came first, so first come first serve I guess.

I really don't see a truly usefull application of a script like this, but what the heck, I'll do it anyways. I'll start it now.

funnyguy1:

It looks like everything you want is possible, but I have some notes and questions.

Quote[/b] ]I want to make a mission with the GB`s handisgnals, so I need .sqs files that can be executed by this system. As you know you can`t use the ofp`s radio codes in order to call support.

I'm not familiar with GB's handsignals, a link would be nice. I disagree about the limitations of the ofp radio codes, I have no problems rigging radio alpha or whatever to say, move a heli to a position to extract a squad.

Quote[/b] ]CAS script for helos (move in to player`s possition, make a mess (limited time) and fly away).

Easy. There is a snag though. It is difficult for the ofp AI to detect infantry on the ground and there's not really anything I can do about that. It would be effective against vehicles though. I suppose it would be possible to just let it know where every enemy soilder is in an area, it would be too effective then however. Maybe with some messing around, I could find a nice balance.

Quote[/b] ]Would this be possible to lase the targets for indirect strikes like in CoC arty? A helo targets the lased spot and fires missile, no matter where it`s pointed.

Almost certainly possible, although I've never tried it. This one'll be fun to work out.

Quote[/b] ]Precision strike for a10 or other aircraft (realistic altitude and speed), for both mapclicked or lased targets.

I actually did something with this a long time ago. Well, on mapclick, not I'll have to see if I still have it and revamp it so it's not another embarrasment.

Quote[/b] ]evac script for helo that I could incorporate with GB`s handsignals

Again, the only wild card here is the gb's hand signals. This can be done with the radio easilly, in fact the scripts above provide the means to do it. I can find out more if you link me to the hand signals however.

Quote[/b] ]ressuplyscript where ammo creates are dropped from a helo, not spawned over the area

Yes, this can be done. FYI though, helicopters tend to land and unload their cargo on the ground. Parachutes are mostly used for fixed wing aircraft providing resupply. Although I suppose that a script to make ANY flyer be able to do this would be good.

funnyguy1 · July 1, 2004

Ok, thx for the attention...I`ll post a larger comment later, now I`m just doing what I think I should do...

HANDSIGNALS THREAD!

edit:

Firstly, you can`t use the standard radio comms along with the hs signals as far as I`m concerned...

Secondly, you should contact General Barron if you want to know more about it (and certainly you should try it), If I knew how to use this kind of knowledge I would ask him myslef .

2024-12-18T23:26:13Z

Thank you ColonelSandersLite' would be great to see that. I didnt really expect anything to materialize, so this is really great.

I have some, I say some references of how to use units from spawns in CTI, but the scripting is so mixed with other checks for the cti mission its hard, very hard to pick out whats needed.

A few very nice features in using spawned units and then of course sending them around to do whatever is needed-

Spawned units cane be thrown in a mission at any time, where maybe in some cases this would reduce lag (like cti res spawns), reinforcement spawns would be another good example, of course done in a reasonable way, keeping the spawns far away from the battle they are reinforcing, in my particular mission the spawns would occur in a few 'primary' town bases which would send them out to battles across the map.

The real big plus in using not just spawns, but also markers to move units, u can change their path plans, unlike thru the editor where once u start setting waypoints thats it, those units can only follow that waypoint system, thru using markers and script if certain events occurr within the mission the script can 're-assign' units to new plans, making a mission more versitile.

So really this type of script is more directed towards larger scale missions that may either use alot of units which some of them could be spawned at appropriate times and/or missions that could use multiple plans for unit groups depending on certain criteria during the mission.

ColonelSandersLite · March 10, 2006

Ok Special Ed and anyone that wants it,

Here's the script with a sample mission below.

When editing the sample mission, be sure to turn on markers so you can see what's going on. Also, note that there are observers at various locations. These should be made playable whenever you want to see the actions.

Ok, script first:

<table border="0" align="center" width="95%" cellpadding="0" cellspacing="0"><tr><td>Code Sample </td></tr><tr><td id="CODE">;Spawn Mechanized Infantry Squad By ColonelSandersLite V1.0

; Usage:

; Create 4 Markers, name them so you will remember them.

; The first marker will be where your unit will spawn

; The second marker will be where your unit will unload at

; The third marker is the infantry units objective

; The fourth marker is the Vehicles Objective

; Create 2 men (ungrouped) and name their groups by putting mygroupname = group this in their init feild.

; The group names must be different.

; Create a trigger/script/whatever that calls this script. Parameter details below

; ["myVehType", "mySpawnMarker", numberOfCrewVehNeeds, "myCrewType", apcGroupName, infSquadGroupName, numberOfSoilderType1, "soilderType1", numberOfSoilderType2, "soilderType2", numberOfSoilderType3, "soilderType3", numberOfSoilderType4, "soilderType4", numberOfSoilderType5, "soilderType5", numberOfSoilderType6, "soilderType6", infantrySkillLevel, "test_apc_unloadW", "test_apc_objW", "test_squad_objW", "myAPCBehavior", "myAPCCombatMode", "myInfSquadBehavior", "myInfSquadCombatMode", timeForAPCToWaitAfterUnloadingSquad] exec "spawnMechInfSquad.sqs"

; Example:

; ["Bradley", "test_spawnW", 3, "SoldierWCrew", WSpawnedAPCGroup, WSpawnedSquadGroup, 1, "OfficerW", 1, "SoldierWG", 2, "SoldierWLAW", 1, "SoldierWMG", 1, "SoldierWB", 0, "SoldierWAT", 0.5, "test_apc_unloadW", "test_apc_objW", "test_squad_objW", "COMBAT", "RED", "COMBAT", "RED", 180] exec "spawnMechInfSquad.sqs"

; More information on accepted parameters

; "myVehType"

; Vehicle Types Sorted by Side, and type. Not all inclusive I'm sure.

; "M113" "Bradley" "M113Ambul" "Truck5t" "Truck5tOpen"

; "HMMWV" "Jeep" "JeepMG" "BoatW"

; "BMP" "BMP2" "BMPAmbul" "UAZ" "Ural"

; "UralRepair" "UralReammo" "UralRefuel" "BRDM" "Scud"

; "BoatE"

; "BMPRes" "TruckV3SG" "GJeep" "TruckV3SCivil" "TruckV3SGRefuel"

; "TruckV3SGRepair" "TruckV3SGReammo" "UAZG" "SGUAZG" "GJeep"

; "SkodaBlue" "SkodaRed" "SkodaGreen"

; "myCrewType"

; Unit Types Sorted By Side. Also not all inclusive.

; "Civilian" "Civilian2" "SoldierWB"

; "SoldierWG" "SoldierWMedic" "SoldierWCrew" "SoldierWPilot" "SoldierWMG"

; "SoldierWLAW" "SoldierWAT" "SoldierWAA" "SoldierWMortar" "SoldierWSniper"

; "SoldierWSaboteurPipe" "SoldierWSaboteurDay" "SoldierWMiner" "OfficerWNight"

; "SoldierWCaptive"

; "SoldierEB" "SoldierWFakeE" "SoldierEG" "SoldierEMedic" "SoldierECrew"

; "SoldierEPilot" "SoldierEMG" "SoldierELAW" "SoldierEAT" "SoldierEAA"

; "SoldierEMiner" "OfficerE" "OfficerENight" "GeneralE" "Angelina"

; "SoldierESniper" "SoldierESaboteurPipe" "SoldierEFakeW"

; "SoldierGB" "SoldierGMedic" "SoldierGCrew" "SoldierGPilot" "SoldierGG"

; "SoldierGMG" "SoldierGLAW" "SoldierGAT" "SoldierGAA" "OfficerG"

; "OfficerGNight" "SoldierGFakeE" "SoldierGFakeC" "SoldierGFakeC2"

; apcGroupName, infSquadGroupName

; These should be the group names of the men created earlier. As a note, those men should be put

; someplace practically inaccessable and secret, and WILL be killed by the script.

; numberOfSoilderTypeX, "soilderType1"

; These allow you to mix and match different soilder types in the squad. 2, "SoldierWLAW" puts

; 2 west LAW soilders in the squad. Note you are limited to six different unit types.

; numberOfSoilderType1 must be at least 1-12. All the others can be 0-12. The types are listed above

; infantrySkillLevel

; A decimal number between and including 0 and 1. This sets the skill level of every man in the squad

; "myAPCBehavior", "myAPCCombatMode", "myInfSquadBehavior", "myInfSquadCombatMode"

; Valid Behaviors

; "SAFE" "AWARE" "COMBAT" "CARELESS" "STEALTH"

; Valid Combat Modes

; "BLUE" =Never Fire

; "GREEN" =Hold Fire

; "WHITE" =Hold Fire, Engage At Will

; "YELLOW" =Open Fire (stay where you are at)

; "RED" =Open Fire, Engage At Will (seek targets but stay near leader)

; timeForAPCToWaitAfterUnloadingSquad

; this is the number of seconds the apc will wait before moving out. 0 is valid, although I reccomend

; you at least give the squad time to clear out before moving so the vehicle doesn't display some of ofp's

; ai quirks.

; This is especially usefull if the vehicle is an apc that is going to support an attack by the infantry squad

; In this fashion, it can be tweaked to act similar to a bounding overwatch, or perhaps wait until the infantry

; has already made contact with the enemy before moving in. This would reduce the chance of getting slagged by

; someone with a LAW/RPG considerably since it would then have mutual support from the infantry.

; BEGIN SCRIPT

; Get All Passed Data.

_vehicleType = _this select 0

_spawnLocMarker = _this select 1

_numCrew = _this select 2

_crewType = _this select 3

_crewGroup = _this select 4

_squadGroup = _this select 5

_numSquad1 = _this select 6

_typeSquad1 = _this select 7

_numSquad2 = _this select 8

_typeSquad2 = _this select 9

_numSquad3 = _this select 10

_typeSquad3 = _this select 11

_numSquad4 = _this select 12

_typeSquad4 = _this select 13

_numSquad5 = _this select 14

_typeSquad5 = _this select 15

_numSquad6 = _this select 16

_typeSquad6 = _this select 17

_squadSkill = _this select 18

_apcUnload = _this select 19

_apcObjective = _this select 20

_squadObjective = _this select 21

_apcBehavior = _this select 22

_apcCombatMode = _this select 23

_squadBehavior = _this select 24

_squadCombatMode = _this select 25

_waitTime = _this select 26

; initialize variables.

_crewSpawnPos = [(getmarkerpos _spawnLocMarker select 0) + 2, (getmarkerpos _spawnLocMarker select 1) + 2,(getmarkerpos _spawnLocMarker select 2)]

_squadSpawnPos = [(getmarkerpos _spawnLocMarker select 0) - 2, (getmarkerpos _spawnLocMarker select 1) - 2,(getmarkerpos _spawnLocMarker select 2)]

; Spawn the vehicle.

_apc = _vehicleType createVehicle getmarkerpos _spawnLocMarker

; Spawn the vehicle's crew, displays a warning if the number supplied is invalid.

_counter = 0

#crewCreate

? _counter == 0 : _crewType createunit [_crewSpawnPos, _crewGroup, "", 1, "CORPORAL"]

? _counter == 0 : (units _crewGroup select 0) setDammage 1

? _counter == 0 : [(units _crewGroup select 0)] join GrpNull

? _counter == 1 : _crewType createunit [_crewSpawnPos, _crewGroup, "", 1, "SERGEANT"]

? _counter == 2 : _crewType createunit [_crewSpawnPos, _crewGroup, "", 1, "LIEUTNANT"]

? _counter > 2 : hintC "spawnMechInfSquad.sqs param 3, numCrew invalid. Valid Range is 1 to 3"

_counter = _counter + 1

?_counter != _numCrew : goto "crewCreate"

; Move the crew into their positions.

_counter = 0

#crewAssign

; _crewType createUnit [(getmarkerpos _spawnLocMarker), _crewGroup, "", 1, "PRIVATE"]

? _counter == 0 : (units _crewGroup select 0) MoveInDriver _apc

? _counter == 1 : (units _crewGroup select 1) MoveInGunner _apc

? _counter == 2 : (units _crewGroup select 2) MoveInCommander _apc

? _counter > 2 : hintC "spawnMechInfSquad.sqs param 3, numCrew invalid. Valid Range is 1 to 3"

(units _crewGroup select _counter) SetCombatMode _apcCombatMode

(units _crewGroup select _counter) SetBehaviour _apcBehavior

_counter = _counter + 1

?_counter != _numCrew : goto "crewAssign"

; Spawn the squad. Unit Type 1

_counter = 0

#squadSpawn1

? _numSquad1 == 0 : hintC "spawnMechInfSquad.sqs param 7, numSquad1 invalid. Valid Range is 1 to 12"; goto "endSquadSpawn1"

_typeSquad1 createunit [_squadSpawnPos, _squadGroup, "", _squadSkill, "SERGEANT"]

? _counter == 0 : (units _squadGroup select 0) setDammage 1

? _counter == 0 : [(units _squadGroup select 0)] join GrpNull

_counter = _counter + 1

?_counter != _numSquad1 : goto "squadSpawn1"

#endSquadSpawn1

; Spawn the squad. Unit Type 2

_counter = 0

#squadSpawn2

? _numSquad2 == 0 : goto "endSquadSpawn2"

_typeSquad2 createunit [_squadSpawnPos, _squadGroup, "", _squadSkill, "CORPORAL"]

_counter = _counter + 1

?_counter != _numSquad2 : goto "squadSpawn2"

#endSquadSpawn2

; Spawn the squad. Unit Type 3

_counter = 0

#squadSpawn3

? _numSquad3 == 0 : goto "endSquadSpawn3"

_typeSquad3 createunit [_squadSpawnPos, _squadGroup, "", _squadSkill, "CORPORAL"]

_counter = _counter + 1

?_counter != _numSquad3 : goto "squadSpawn3"

#endSquadSpawn3

; Spawn the squad. Unit Type 4

_counter = 0

#squadSpawn4

? _numSquad4 == 0 : goto "endSquadSpawn4"

_typeSquad4 createunit [_squadSpawnPos, _squadGroup, "", _squadSkill, "CORPORAL"]

_counter = _counter + 1

?_counter != _numSquad4 : goto "squadSpawn4"

#endSquadSpawn4

; Spawn the squad. Unit Type 5

_counter = 0

#squadSpawn5

? _numSquad5 == 0 : goto "endSquadSpawn5"

_typeSquad5 createunit [_squadSpawnPos, _squadGroup, "", _squadSkill, "SERGEANT"]

_counter = _counter + 1

?_counter != _numSquad5 : goto "squadSpawn5"

#endSquadSpawn5

; Spawn the squad. Unit Type 6

_counter = 0

#squadSpawn6

? _numSquad6 == 0 : goto "endSquadSpawn6"

_typeSquad6 createunit [_squadSpawnPos, _squadGroup, "", _squadSkill, "SERGEANT"]

_counter = _counter + 1

?_counter != _numSquad6 : goto "squadSpawn6"

#endSquadSpawn6

; Assign the squad members to an array

_squad = units _squadGroup

; count the squad members

_numberOfSquadMembers = count _squad

; Move the squad into the vehicle's cargo

_counter = 0

#squadAssign

(_squad select _counter) MoveInCargo _apc

_counter = _counter + 1

(_squad select _counter) SetCombatMode _squadCombatMode

(_squad select _counter) SetBehaviour _squadBehavior

?_counter != _numberOfSquadMembers : goto "squadAssign"

; Make the apc move to the unload WP

_apc commandMove getMarkerPos _apcUnload

; Wait for the APC to reach the unload WP

_atWP = false

#waitForAPCToReachWP

; simply the pythagorean theorem

_distanceA = (getpos _apc select 0) - (getMarkerPos _apcUnload select 0)

_distanceB = (getpos _apc select 1) - (getMarkerPos _apcUnload select 1)

_distanceC = sqrt ((_distanceA * _distanceA) + (_distanceB * _distanceB))

? _distanceC <= 10 : _atWP = true

~1

? !_atWP : goto "waitForAPCToReachWP"

;

; APC UNLOAD ROUTINE

; Modified Vehicle Unload by ColonelSandersLite Version 1.0

;

; initialize variables.

_stopped = false

; Stop the vehicle.

_apc action ["Engine Off"]

; This loop checks that the vehicle is stopped and wont let the script progress till it does.

#stoppedCheckLoop

? (velocity _apc select 0 == 0) AND (velocity _apc select 1 == 0) AND (velocity _apc select 2 == 0) : _stopped = true

~1

? !_stopped : goto "stoppedCheckLoop"

; This unloads everyone, quickly.

; reset getOutLoop counter

_tmp = 0

; count the living squad mates

_num = "alive _x" count _squad

#getOutLoop

? (((_squad select _tmp) in _apc) AND (alive (_squad select _tmp))) : unassignVehicle (_squad select _tmp); (_squad select _tmp) action ["eject", _apc]

~.85

_tmp = _tmp + 1

? _tmp < _num : goto "getOutLoop"

; make double sure that everyone is out by runngin the getOutLoop Again without the delay between members

; reset getOutLoop2 counter

_tmp = 0

; count the living squad mates

_num = "alive _x" count _squad

#getOutLoop2

? (((_squad select _tmp) in _apc) AND (alive (_squad select _tmp))) : unassignVehicle (_squad select _tmp); (_squad select _tmp) action ["eject", _apc]

_tmp = _tmp + 1

? _tmp < _num : goto "getOutLoop2"

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;Non-Original Code Block;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; make squad move to objective

_squad commandMove getMarkerPos _squadObjective

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; timer loop to make the vehicle wait a small amount of time after squad disembarks.

_timewaited = 0

#waitLoop

~1

_timewaited = _timewaited + 1

? _timewaited < _waitTime : goto "waitLoop"

;

; END OF APC UNLOAD ROUTINE

;

; make apc move to objective

_apc commandMove getMarkerPos _apcObjective

; finished

Now, the mission.

<table border="0" align="center" width="95%" cellpadding="0" cellspacing="0"><tr><td>Code Sample </td></tr><tr><td id="CODE">version=11;

class Mission

{

addOns[]=

{

"bmp2",

"bradley"

};

randomSeed=16418819;

class Intel

{

};

class Groups

{

items=10;

class Item0

{

side="WEST";

class Vehicles

{

items=2;

class Item0

{

position[]={6113.209961,180.064148,6989.717285};

azimut=85.831902;

id=0;

side="WEST";

vehicle="OfficerW";

player="PLAYER COMMANDER";

leader=1;

rank="CAPTAIN";

skill=0.600000;

text="observer_1";

};

class Item1

{

position[]={6100.331055,181.711899,7007.060547};

azimut=270.000000;

id=1;

side="WEST";

vehicle="SoldierWB";

rank="CAPTAIN";

skill=0.600000;

text="observer_2";

};

class Item1

{

side="WEST";

class Vehicles

{

items=1;

class Item0

{

position[]={1119.549316,89.372643,11493.719727};

id=2;

side="WEST";

vehicle="SoldierWB";

leader=1;

rank="COLONEL";

skill=0.600000;

init="WSpawnedAPCGroup = group this;";

};

class Item2

{

side="WEST";

class Vehicles

{

items=1;

class Item0

{

position[]={1129.315430,89.853889,11494.052734};

id=3;

side="WEST";

vehicle="SoldierWB";

leader=1;

rank="COLONEL";

skill=0.600000;

init="WSpawnedSquadGroup = group this;";

};

class Item3

{

side="WEST";

class Vehicles

{

items=2;

class Item0

{

position[]={6468.914063,141.884995,7138.881348};

azimut=85.831902;

id=4;

side="WEST";

vehicle="OfficerW";

leader=1;

rank="CAPTAIN";

skill=0.600000;

text="observer_1_1";

};

class Item1

{

position[]={6459.533203,141.884995,7156.223633};

azimut=270.000000;

id=5;

side="WEST";

vehicle="OfficerW";

rank="CAPTAIN";

skill=0.600000;

text="observer_2_1";

};

class Item4

{

side="WEST";

class Vehicles

{

items=2;

class Item0

{

position[]={5695.334961,198.705292,7135.165039};

azimut=85.831902;

id=6;

side="WEST";

vehicle="OfficerW";

leader=1;

rank="CAPTAIN";

skill=0.600000;

text="observer_1_2";

};

class Item1

{

position[]={5685.954102,198.947296,7152.507324};

azimut=270.000000;

id=7;

side="WEST";

vehicle="SoldierWB";

rank="CAPTAIN";

skill=0.600000;

text="observer_2_2";

};

class Item5

{

side="EAST";

class Vehicles

{

items=2;

class Item0

{

position[]={1818.965088,98.718559,5718.448730};

azimut=258.248993;

id=8;

side="EAST";

vehicle="OfficerE";

leader=1;

rank="CAPTAIN";

skill=0.600000;

text="observer_1_3";

};

class Item1

{

position[]={1816.285522,98.114128,5721.408203};

azimut=270.000000;

id=9;

side="EAST";

vehicle="SoldierEB";

rank="CAPTAIN";

skill=0.600000;

text="observer_2_3";

};

class Item6

{

side="EAST";

class Vehicles

{

items=1;

class Item0

{

position[]={10980.062500,24.525000,11671.916016};

id=10;

side="EAST";

vehicle="SoldierEB";

leader=1;

rank="COLONEL";

skill=0.600000;

init="ESpawnedAPCGroup = group this;";

};

class Item7

{

side="EAST";

class Vehicles

{

items=1;

class Item0

{

position[]={10989.828125,24.525000,11672.250000};

id=11;

side="EAST";

vehicle="SoldierEB";

leader=1;

rank="COLONEL";

skill=0.600000;

init="ESpawnedSquadGroup = group this;";

};

class Item8

{

side="EAST";

class Vehicles

{

items=2;

class Item0

{

position[]={2479.701660,82.908936,5329.519531};

azimut=-71.545891;

id=12;

side="EAST";

vehicle="OfficerE";

leader=1;

rank="CAPTAIN";

skill=0.600000;

text="observer_1_1_1";

};

class Item1

{

position[]={2479.718994,82.830223,5319.073730};

azimut=333.461456;

id=13;

side="EAST";

vehicle="OfficerE";

rank="CAPTAIN";

skill=0.600000;

text="observer_2_1_1";

};

class Item9

{

side="EAST";

class Vehicles

{

items=2;

class Item0

{

position[]={1399.872192,69.730782,5864.356445};

azimut=85.831902;

id=14;

side="EAST";

vehicle="OfficerE";

leader=1;

rank="CAPTAIN";

skill=0.600000;

text="observer_1_2_1";

};

class Item1

{

position[]={1394.418945,69.279915,5857.544922};

azimut=136.024734;

id=15;

side="EAST";

vehicle="SoldierEB";

rank="CAPTAIN";

skill=0.600000;

text="observer_2_2_1";

};

class Markers

{

items=10;

class Item0

{

position[]={6494.594727,141.884995,7108.217285};

name="test_spawnW";

type="Empty";

};

class Item1

{

position[]={5727.100586,192.599991,7074.211426};

name="test_squad_objW";

type="Empty";

};

class Item2

{

position[]={6126.424805,178.031570,6978.399414};

name="test_apc_unloadW";

type="Empty";

};

class Item3

{

position[]={5748.052246,208.777695,7160.914551};

name="test_apc_objW";

type="Empty";

};

class Item4

{

position[]={874.660522,30.056107,11576.781250};

name="asdf";

text="West Spawn Placeholders";

type="Flag1";

colorName="ColorGreen";

a=5.000000;

b=5.000000;

};

class Item5

{

position[]={9750.765625,1.520651,11682.756836};

name="asdf_1";

text="East Spawn Placeholders";

type="Flag1";

a=4.000000;

b=4.000000;

};

class Item6

{

position[]={2449.780029,82.883934,5345.060547};

name="test_spawnE";

type="Empty";

};

class Item7

{

position[]={1235.105347,65.474998,5973.201172};

name="test_squad_objE";

type="Empty";

};

class Item8

{

position[]={1781.427124,95.467613,5710.897949};

name="test_apc_unloadE";

type="Empty";

};

class Item9

{

position[]={1448.115845,75.225960,5838.219238};

name="test_apc_objE";

type="Empty";

};

class Sensors

{

items=2;

class Item0

{

position[]={6133.463867,168.764786,7176.156738};

a=0.000000;

b=0.000000;

activationBy="ALPHA";

age="UNKNOWN";

text="Spawn West";

expActiv="[""Bradley"", ""test_spawnW"", 3, ""SoldierWCrew"", WSpawnedAPCGroup, WSpawnedSquadGroup, 1, ""OfficerW"", 1, ""SoldierWG"", 2, ""SoldierWLAW"", 1, ""SoldierWMG"", 1, ""SoldierWB"", 0, ""SoldierWAT"", 0.5, ""test_apc_unloadW"", ""test_apc_objW"", ""test_squad_objW"", ""COMBAT"", ""RED"", ""COMBAT"", ""RED"", 180] exec ""spawnMechInfSquad.sqs""";

class Effects

{

};

class Item1

{

position[]={1887.892578,102.871704,5773.496582};

a=0.000000;

b=0.000000;

activationBy="BRAVO";

age="UNKNOWN";

text="Spawn East";

expActiv="[""BMP2"", ""test_spawnE"", 3, ""SoldierECrew"", ESpawnedAPCGroup, ESpawnedSquadGroup, 1, ""OfficerE"", 1, ""SoldierEG"", 2, ""SoldierELAW"", 1, ""SoldierEMG"", 1, ""SoldierEB"", 0, ""SoldierEAT"", 0.5, ""test_apc_unloadE"", ""test_apc_objE"", ""test_squad_objE"", ""COMBAT"", ""RED"", ""COMBAT"", ""RED"", 300] exec ""spawnMechInfSquad.sqs""";

class Effects

{

};

class Intro

{

randomSeed=14504963;

class Intel

{

};

class OutroWin

{

randomSeed=1281539;

class Intel

{

};

class OutroLoose

{

randomSeed=4226563;

class Intel

{

};

--------------------------------------------------

The basic fixed wing laser guided bomb script is done. Works with the blackop(laser) and the oh58's laser designator. and any fixed wing aircraft you choose to use. Heck, it probably would work with a helicopter should you really want to drop laser guided bombs from a rotorary wing aircraft for some reason.

Once I sleep, I'll flesh it out a little more, test it some more, and document it. Then I'll post it. In the mean time, .

2024-12-18T23:26:14Z

Wow

Thanks a lot ColonelSandersLite, looks like it was alot more work than I realized to put that together, extremely kind of you.

I have decided that if, big IF this mission of mine gets done I will be giving you the credit for this script, wether I use the whole thing or just parts of it, its not much and I know its not like your doing this expecting something in return, but it is the least I can do.

I.... lol, dont know what to say, wow, Im confident after looking over the whole script that I can edit it as I see fit to get stuff goin right when the time comes, otherwise if it were not for your very generous help just looking at the size of the script I can see it would have been a task to figure it all out 10 times what I thought it would be.

Cheers to you.

ColonelSandersLite · March 10, 2006

Ah hell, it wasn't nothin. I just like writing code people will find usefull. Wether it's c++, java, or ofp++ .

Anyways, there is a small thing you can do in return, put the modified script up here. Hell, even in the same thread if you like. The more scripts like this available, the better...

Anyways, now I've got to work on funnyguy1's stuff. He sure did give me a stack of things to have fun with.

2024-12-18T23:26:14Z

No problem. Its defenitley seeming a great idea to have alot more scripts that cover basic actions of a mission, ofpec had a lot of stuff, but it was still lacking some in having scripts that would cover basic actions of certain applications, that is not just limited to a particular action like helo drops, but a slew of actions that would make up a 'basic' function that could be used over and over again in larger scale missions, which of course would broaden the horizens for mission makers with little coding/scripting knowledge. It almost does seem odd to me that somehow the editor wasnt set up to utilize spawned units and also multiple waypoint systems for units and groups, it would have made things much easier for these applications, which are used often in large scale missions and certainly used alot in big MP missions.

Gl with those new scripts and thanks again for helping out the user mission creating community.

ColonelSandersLite · March 10, 2006

Just an update this time. I'm working on the LGB script, and it's working pretty well right now. I had hit a snag using spawned pilots and planes, but I worked around it. If only createunit returned a local unit name like createvehicle.

Still, a solution has presented itself and I now have a pretty badass script nearly ready to release. I'll post it once I finish testing and documentation tomorrow.

I also have an idea for a decent single player/coop mission that uses some of the scripts seen here. I think I just might put it together once I've finished this LGB script. Just for shits and giggles.

mattxr · January 17, 2005

sorry to hyjack your thred but can anyone tell me whats what for this.. [0,0,0] which one is up and down and left and right so on??

ColonelSandersLite · March 10, 2006

Not a problem.

[0,0,0] is [x,y,z]

When refering to position, these coordinate with map coordinates in meters (I think it's meters).

When refering to velocity, it's in meters/second.

I'm thinking east and north are higher, but I quickly forget such things.

Create a quick test mission with some guy as the player.

Put this in a text file called reportpos.sqs in the mission folder.

<table border="0" align="center" width="95%" cellpadding="0" cellspacing="0"><tr><td>Code Sample </td></tr><tr><td id="CODE">_veh = _this select 0

#reporting

_report = format["X %1 Y %2 Z %3", (getpos _veh select 0), (getpos _veh select 1), (getpos _veh select 2)]

_veh GlobalChat _report

goto "reporting"

and put: [this] exec "reportpos.sqs" in the guys init bar. This will tell you for sure.

ColonelSandersLite · March 10, 2006

Now, for the LGB script, documented and tested.

*deleted by me, updated version below*

Garcia · August 31, 2002

sorry to hyjack your thred but can anyone tell me whats what for this.. [0,0,0] which one is up and down and left and right so on?? Â

[x,y,z] where x is east/west, y is north/south and z is up/down (altitude). It starts in the bottom left corner (so [0,0,0] will be in the bottom left corner).

ColonelSandersLite · March 10, 2006

Now, it's time to post the Laser Designated, Fixed Wing Aircraft Launched, Air to Surface Missile Script.

*deleted by me, updated version below*

ColonelSandersLite · March 10, 2006

1: The laser guided bomb and air to surface missile scripts, modified to support General Barrons Hand signals mod.

2: Due to the nature of HS missions, it's not practical to post the contents of all the mission related files here. If anyone wants the sample HS mission with the scripts, let me know and I'll e-mail it to you. If a bunch of people want it, I'll see about getting it hosted.

So, the scripts:

fixedWingLaserHS.sqs

<table border="0" align="center" width="95%" cellpadding="0" cellspacing="0"><tr><td>Code Sample </td></tr><tr><td id="CODE">; Fixed Wing Laser Guided Bombs by ColonelSandersLite Version V1.0

; Modified to support General Barron's Hand Signals

; Instructions:

; 1: Create a valid HS mission by following the directions from the HS Mission Notes.

; In the Editor:

; 2: Create 1 Marker (empty), name it so you will remember it.

; This marker will be used by the script to keep track of the lased target.

; 3: Create a trigger that covers the area that can be lased, name it whatever you want. I

; used CSL_FWAS_unitlist . It must be an "anybody present, repeatedly, condition this,

; on activation blank" type.

; 4: Create 1 man (ungrouped) and name his group by putting mygroupname = group this

; in his init feild. I used CSL_FWAS_groupAirSupport . This man should be tucked out of the way

; 5: Create a trigger that covers the man above, it must be named "CSL_FWAS_PilotList" and

; be an "anybody present, repeatedly, condition this, on activation blank" type.

; I reccomend a 500X500 rectangle.

; In windows:

; 6: Put fixedWingLaserHS.sqs in the support folder of your choice.

; I chose \support\fixedWingLaserHS\fixedWingLaserHS.sqs

; Time to start playing with the sqs files now:

; 7: In "init.sqs", Just below the line that says ";YOU CAN EDIT BELOW THIS POINT" insert:

; myNumberOfStrikes = X (leave off the; at the begining)

; Where myNumberOfStrikes is a global variable name (I used CSL_FWAS_NumberOfStrikesAvailable)

; and X is the number of strikes you want to be available (I used 9999 for the sample).

; 8: In "hs_init.sqs", just above the line that says

; ";code to be executed when radio is first used. If you don't want anything, just use empty braces"

; insert: (leave off the; at the begining of these lines)

; _tmp = ["myText", "mypath\fixedWingLaserHS.sqs"]

; _rto_opts = _rto_opts + [_tmp]

; Where myText is the text you want to display in the radio dialog, and myPath is the path to

; fixedWingLaserHS.sqs from step 6.

; Example: (leave off the; at the begining of these lines)

; _tmp = ["Request LGB Air Strike", "support\fixedWingLaserHS\fixedWingLaserHS.sqs"]

; _rto_opts = _rto_opts + [_tmp]

; 9: Edit the values as instructed below.

; BEGIN SCRIPT

; Get All Passed Data.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Changed for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; change: HS Radio System cannot support Parameters. The Values must be altered by hand.

;_delayBeforeInbound = _this select 0

;_unitList = _this select 1

;_attackMarker = _this select 2

;_approachFrom = _this select 3

;_exitTo = _this select 4

;_flyHeight = _this select 5

;_group = _this select 6

;_acType = _this select 7

;_crewType = _this select 8

; CSL_FWAS_AttackTarget should be changed to whatever you named the marker you're using in step 2.

_attackMarker = "CSL_FWAS_AttackTarget"

; list is game code and is mandatory. CSL_FWAS_unitlist should be changed to whatever you named the trigger

; covering the paintable area as in step 3.

_unitList = list CSL_FWAS_unitlist

; CSL_FWAS_groupAirSupport should be changed to the group name from step 4.

_group = CSL_FWAS_groupAirSupport

; list is game code and is mandatory. CSL_FWAS_PilotList should be changed to whatever you named the trigger

; covering the paintable area as in step 5.

_pilotList = list CSL_FWAS_PilotList

; This number lets you set the time between the call for support and the actual attack run of the aircraft.

; The number is in seconds.

_delayBeforeInbound = 30

; Dictates "approach target from the" direction. Valid Values:

; "n" "ne" "e" "se" "s" "sw" "w" "nw"

_approachFrom = "w"

; Dictates the "exit target area to the" direction. Must be different from "_approachFrom" above.

; Valid Values:

; "n" "ne" "e" "se" "s" "sw" "w" "nw"

_exitTo = "ne"

; The aircraft will stay this many meters above the ground. Given ofp's bad pilot AI, this isn't

; going to be too accurate. It is suggested that you make this number at least 50 and do a little

; testing to see what's reliable in your particular situation. On Flat maps, you can probably get

; it pretty low, but you need some room for the aircraft to clear the blast.

_flyHeight = 50

; The type of aircraft providing support. Tested BIS values:

; "Su25"

; "A10"

; "A10LGB"

; "Cessna"

_acType = "A10"

; The pilot type. Tested BIS values:

; "SoldierWPilot"

; "SoldierEPilot"

; "SoldierGPilot"

; "Civilian"

_crewType = "SoldierWPilot"

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Added for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; this is the time the player won't be able to use the radio after calling the strike

hs_rto_dly = 5

; finished, the support should work now.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Added for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; takes care of Number of strikes check and RTO messages

? ((CSL_FWAS_NumberOfStrikesAvailable == 0) AND (call hs_hearRTO)) : [units _group select 0, "Negative, there are no strike aircraft on station, over."] call hs_sidechat

? (CSL_FWAS_NumberOfStrikesAvailable == 0) : exit

CSL_FWAS_NumberOfStrikesAvailable = CSL_FWAS_NumberOfStrikesAvailable - 1

? call hs_hearRTO : [units _group select 0, "Roger, setting up for attack run, over."] call hs_sidechat

; delay the script's execution the specified number of seconds

~_delayBeforeInbound

; get the designated spot

_designator = objNull

"if (typeOf _x == ""LaserTargetW"") then {_designator = _x}" forEach _unitList

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Changed for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; if nothing is designated, abort the attack run

; ? (IsNull _designator) : units _group select 0 sideChat "We are not receiveing a signal, aborting run, over."; exit

; change: converted to HS message system

? ((IsNull _designator) AND (call hs_hearRTO)) : [units _group select 0, "We are not receiveing a signal, aborting run, over."] call hs_sidechat

? (IsNull _designator) : exit

; if something is designated, set the marker's position to the designated spot.

_attackMarker setMarkerPos [getPos _designator select 0, getPos _designator select 1]

; check that the approach and exit directions are valid. If they're not, abort the script

? _approachFrom == _exitTo : hintC "The AI performs eratically when you set the approach and exit directions to be the same. Please set them to different directions"; exit

_validApproach = false

_validExit = false

? _approachFrom == "n" : _validApproach = true

? _approachFrom == "e" : _validApproach = true

? _approachFrom == "s" : _validApproach = true

? _approachFrom == "w" : _validApproach = true

? _approachFrom == "ne" : _validApproach = true

? _approachFrom == "se" : _validApproach = true

? _approachFrom == "sw" : _validApproach = true

? _approachFrom == "nw" : _validApproach = true

? !(_validApproach) : hintC format["The Approach direction specified is invalid. Must be one of ""n"" ""e"" ""s"" ""w"" ""ne"" ""se"" ""sw"" ""nw""."]; exit

? _exitTo == "n" : _validExit = true

? _exitTo == "e" : _validExit = true

? _exitTo == "s" : _validExit = true

? _exitTo == "w" : _validExit = true

? _exitTo == "ne" : _validExit = true

? _exitTo == "se" : _validExit = true

? _exitTo == "sw" : _validExit = true

? _exitTo == "nw" : _validExit = true

? !(_validExit) : hintC format["The exit direction specified is invalid. Must be one of ""n"" ""e"" ""s"" ""w"" ""ne"" ""se"" ""sw"" ""nw""."]; exit

; spawn the plane and the pilot

_aircraft = _acType createVehicle [getPos ((units _group) select 0) select 0, getPos ((units _group) select 0) select 2, _flyHeight]

_crewType createunit [getPos ((units _group) select 0), _group, "", 1, "PRIVATE"]

; give the pilot time to spawn and show up in the _pilotList

~1

; get the pilot from the pilot list, and stick him in the cockpit.

"if (typeOf _x == _crewType) then {_x assignAsDriver _aircraft; _x moveInDriver _aircraft}" forEach (_pilotList)

_pilot = driver _aircraft

; set the strike aircraft's waypoint and flight altitude

_aircraft doMove [getMarkerPos _attackMarker select 0, getMarkerPos _attackMarker select 1, _flyHeight]

_aircraft flyInHeight _flyHeight

; set the pilot to be reckless so he doesn't try to engage other opponents

"_x setCombatMode ""BLUE""" foreach units _group

"_x setBehaviour ""CARELESS""" foreach units _group

; remove all armament from the plane to help enforce him not engaging other opponents

removeAllWeapons _aircraft

; start the aircraft on his flight path.

? _approachFrom == "n" : _aircraft setPos [(getMarkerPos _attackMarker select 0), (getMarkerPos _attackMarker select 1) + 2500, _flyHeight]; _aircraft setDir 180; _aircraft setVelocity [0,-111,0]

? _approachFrom == "e" : _aircraft setPos [(getMarkerPos _attackMarker select 0) + 2500, (getMarkerPos _attackMarker select 1), _flyHeight]; _aircraft setDir 270; _aircraft setVelocity [-111,0,0]

? _approachFrom == "s" : _aircraft setPos [(getMarkerPos _attackMarker select 0), (getMarkerPos _attackMarker select 1) - 2500, _flyHeight]; _aircraft setDir 0; _aircraft setVelocity [0,111,0]

? _approachFrom == "w" : _aircraft setPos [(getMarkerPos _attackMarker select 0) - 2500, (getMarkerPos _attackMarker select 1), _flyHeight]; _aircraft setDir 90; _aircraft setVelocity [111,0,0]

? _approachFrom == "ne" : _aircraft setPos [(getMarkerPos _attackMarker select 0) + 1768, (getMarkerPos _attackMarker select 1) + 1768, _flyHeight]; _aircraft setDir 225; _aircraft setVelocity [-78,-78,0]

? _approachFrom == "se" : _aircraft setPos [(getMarkerPos _attackMarker select 0) + 1768, (getMarkerPos _attackMarker select 1) - 1768, _flyHeight]; _aircraft setDir 315; _aircraft setVelocity [-78,78,0]

? _approachFrom == "sw" : _aircraft setPos [(getMarkerPos _attackMarker select 0) - 1768, (getMarkerPos _attackMarker select 1) - 1768, _flyHeight]; _aircraft setDir 45; _aircraft setVelocity [78,78,0]

? _approachFrom == "nw" : _aircraft setPos [(getMarkerPos _attackMarker select 0) - 1768, (getMarkerPos _attackMarker select 1) + 1768, _flyHeight]; _aircraft setDir 135; _aircraft setVelocity [78,-78,0]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Changed for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; announce the begining of the attack run to the player

;_pilot sideChat "Inbound on attack run, over"

; change: converted to HS message system

? call hs_hearRTO : [_pilot, "Inbound on attack run, over."] call hs_sidechat

; keep checking to see that the target is still lased. If it isn't, abort the run.

; also moves the wp to keep the plane heading towards the lased target, even if it moves.

_halfwayToWP = false

#waitForAircraftToGethalfwayToWP

_designator = objNull

"if (typeOf _x == ""LaserTargetW"") then {_designator = _x}" forEach _unitList

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Changed for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;? (IsNull _designator) : _pilot sideChat "Signal Lost, aborting run, over."; goto "abortRun"

; change: converted to HS message system

? ((IsNull _designator) AND (call hs_hearRTO)) : [_pilot, "Signal Lost, aborting run, over."] call hs_sidechat

? (IsNull _designator) : goto "abortRun"

_attackMarker setMarkerPos [getPos _designator select 0, getPos _designator select 1]

_aircraft doMove [getMarkerPos _attackMarker select 0, getMarkerPos _attackMarker select 1, _flyHeight]

; simply the pythagorean theorem

_distanceA = (getpos _aircraft select 0) - (getMarkerPos _attackMarker select 0)

_distanceB = (getpos _aircraft select 1) - (getMarkerPos _attackMarker select 1)

_distanceC = sqrt ((_distanceA * _distanceA) + (_distanceB * _distanceB))

? _distanceC <= 1000 : _halfwayToWP = true

~1

? !_halfwayToWP : goto "waitForAircraftToGethalfwayToWP"

; (faster) keep checking to see that the target is still lased. If it isn't, abort the run.

; also moves the wp to keep the plane heading towards the lased target, even if it moves.

_atWP = false

#waitForAircraftToReachWP

_designator = objNull

"if (typeOf _x == ""LaserTargetW"") then {_designator = _x}" forEach _unitList

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Changed for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;? (IsNull _designator) : _pilot sideChat "Signal Lost, aborting run, over."; goto "abortRun"

; change: converted to HS message system

? ((IsNull _designator) AND (call hs_hearRTO)) : [_pilot, "Signal Lost, aborting run, over."] call hs_sidechat

? (IsNull _designator) : "abortRun"

_attackMarker setMarkerPos [getPos _designator select 0, getPos _designator select 1]

_aircraft doMove [getMarkerPos _attackMarker select 0, getMarkerPos _attackMarker select 1, _flyHeight]

; simply the pythagorean theorem

_distanceA = (getpos _aircraft select 0) - (getMarkerPos _attackMarker select 0)

_distanceB = (getpos _aircraft select 1) - (getMarkerPos _attackMarker select 1)

_distanceC = sqrt ((_distanceA * _distanceA) + (_distanceB * _distanceB))

? _distanceC <= 50 : _atWP = true

; aborts the run if the plane over shot the target without dropping the bomb.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Changed for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;? _distanceC >1000 : _pilot sideChat "Couldn't keep lock, attack run aborted, over"; goto "abortRun"

; change: converted to HS message system

? ((_distanceC > 1000) AND (call hs_hearRTO)) : [_pilot, "Couldn't keep lock, attack run aborted, over."] call hs_sidechat

? (_distanceC > 1000) : goto "abortRun"

~.25

? !_atWP : goto "waitForAircraftToReachWP"

; drop the bomb when over the target.

"laserGuidedBomb" camcreate [getMarkerPos _attackMarker select 0, getMarkerPos _attackMarker select 1, (getPos _aircraft select 2)-40]

; this marker is used in the event the plane had to abort the run

#abortRun

; this block just makes the plane fly away after the run in the desired direction

? _exitTo == "n" : _exitLocation = [(getMarkerPos _attackMarker select 0), (getMarkerPos _attackMarker select 1) + 5000, _flyHeight]

? _exitTo == "e" : _exitLocation = [(getMarkerPos _attackMarker select 0) + 5000, (getMarkerPos _attackMarker select 1), _flyHeight]

? _exitTo == "s" : _exitLocation = [(getMarkerPos _attackMarker select 0), (getMarkerPos _attackMarker select 1) - 5000, _flyHeight]

? _exitTo == "w" : _exitLocation = [(getMarkerPos _attackMarker select 0) - 5000, (getMarkerPos _attackMarker select 1), _flyHeight]

? _exitTo == "ne" : _exitLocation = [(getMarkerPos _attackMarker select 0) + 3536, (getMarkerPos _attackMarker select 1) + 3536, _flyHeight]

? _exitTo == "se" : _exitLocation = [(getMarkerPos _attackMarker select 0) + 3536, (getMarkerPos _attackMarker select 1) - 3536, _flyHeight]

? _exitTo == "sw" : _exitLocation = [(getMarkerPos _attackMarker select 0) - 3536, (getMarkerPos _attackMarker select 1) - 3536, _flyHeight]

? _exitTo == "nw" : _exitLocation = [(getMarkerPos _attackMarker select 0) - 3536, (getMarkerPos _attackMarker select 1) + 3536, _flyHeight]

_aircraft doMove _exitLocation

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Added for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; change: Added to make communication more consistant with HS Radio System

? ((_atWP) AND (call hs_hearRTO)) : [_pilot, "Weapon deployed, over."] call hs_sidechat

; wait for the plane to extract.

_atWP = false

#waitForAircraftToReachExit

; simply the pythagorean theorem

_distanceA = (getpos _aircraft select 0) - (_exitLocation select 0)

_distanceB = (getpos _aircraft select 1) - (_exitLocation select 1)

_distanceC = sqrt ((_distanceA * _distanceA) + (_distanceB * _distanceB))

? _distanceC <= 1000 : _atWP = true

~.5

? !_atWP : goto "waitForAircraftToReachExit"

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Added for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; change: Added to make communication more consistant with HS Radio System

? (call hs_hearRTO) : [_pilot, "Exiting Mission Area, over."] call hs_sidechat

~1

; once the plane has extracted, delete it so it's not taking resources anymore

deleteVehicle driver _aircraft

deleteVehicle _aircraft

; end of script

fixedWingASMLaserHS.sqs

<table border="0" align="center" width="95%" cellpadding="0" cellspacing="0"><tr><td>Code Sample </td></tr><tr><td id="CODE">; Laser Designated, Fixed Wing Aircraft Launched, Air to Surface Missile Script by ColonelSandersLite Version V1.0

; Modified to support General Barron's Hand Signals

; Credit:

; "xenom" for "hint format["weapons: %1, magazines: %2",weapons this,magazines this]" in this thread:

; http://www.flashpoint1985.com/cgi-bin/ikonboard311/ikonboard.cgi?act=ST;f=7;t=16179;st=15

; used in reccomendation for editors trying to figure out the weapon/magazine names of an aircraft.

; Instructions:

; 1: Create a valid HS mission by following the directions from the HS Mission Notes.

; In the Editor:

; 2: Create 1 Marker (empty), name it so you will remember it.

; This marker will be used by the script to keep track of the lased target.

; 3: Create a trigger that covers the area that can be lased, name it whatever you want. I

; used CSL_FWAS_unitlist . It must be an "anybody present, repeatedly, condition this,

; on activation blank" type.

; 4: Create 1 man (ungrouped) and name his group by putting mygroupname = group this

; in his init feild. I used CSL_FWAS_groupAirSupport . This man should be tucked out of the way

; 5: Create a trigger that covers the man above, name it whatever you want. I

; used CSL_FWAS_PilotList . It must be an "anybody present, repeatedly, condition this,

; on activation blank" type. I reccomend a 500X500 rectangle for size.

; In windows:

; 6: Put fixedWingLaserHS.sqs in the support folder of your choice.

; I chose \support\fixedWingLaserHS\fixedWingLaserHS.sqs

; Time to start playing with the sqs files now:

; 7: In "init.sqs", Just below the line that says ";YOU CAN EDIT BELOW THIS POINT" insert:

; myNumberOfStrikes = X (leave off the; at the begining)

; Where myNumberOfStrikes is a global variable name (I used CSL_FWAS_NumberOfStrikesAvailable)

; and X is the number of strikes you want to be available (I used 9999 for the sample).

; 8: In "hs_init.sqs", just above the line that says

; ";code to be executed when radio is first used. If you don't want anything, just use empty braces"

; insert: (leave off the; at the begining of these lines)

; _tmp = ["myText", "mypath\fixedWingLaserHS.sqs"]

; _rto_opts = _rto_opts + [_tmp]

; Where myText is the text you want to display in the radio dialog, and myPath is the path to

; fixedWingLaserHS.sqs from step 6.

; Example: (leave off the; at the begining of these lines)

; _tmp = ["Request LGB Air Strike", "support\fixedWingLaserHS\fixedWingLaserHS.sqs"]

; _rto_opts = _rto_opts + [_tmp]

; 9: Edit the values as instructed below.

; BEGIN SCRIPT

; Get All Passed Data.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Changed for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; change: HS Radio System cannot support Parameters. The Values must be altered by hand.

;_delayBeforeInbound = _this select 0

;_unitList = _this select 1

;_attackMarker = _this select 2

;_approachFrom = _this select 3

;_exitTo = _this select 4

;_flyHeight = _this select 5

;_group = _this select 6

;_acType = _this select 7

;_crewType = _this select 8

; CSL_FWAS_AttackTarget should be changed to whatever you named the marker you're using in step 2.

_attackMarker = "CSL_FWAS_AttackTarget"

; list is game code and is mandatory. CSL_FWAS_unitlist should be changed to whatever you named the trigger

; covering the paintable area as in step 3.

_unitList = list CSL_FWAS_unitlist

; CSL_FWAS_groupAirSupport should be changed to the group name from step 4.

_group = CSL_FWAS_groupAirSupport

; list is game code and is mandatory. CSL_FWAS_PilotList should be changed to whatever you named the trigger

; covering the paintable area as in step 5.

_pilotList = list CSL_FWAS_PilotList

; This number lets you set the time between the call for support and the actual attack run of the aircraft.

; The number is in seconds.

_delayBeforeInbound = 30

; Dictates "approach target from the" direction. Valid Values:

; "n" "ne" "e" "se" "s" "sw" "w" "nw"

_approachFrom = "w"

; Dictates the "exit target area to the" direction. Must be different from "_approachFrom" above.

; Valid Values:

; "n" "ne" "e" "se" "s" "sw" "w" "nw"

_exitTo = "ne"

; The aircraft will stay this many meters above the ground. Given ofp's bad pilot AI, this isn't

; going to be too accurate. It is suggested that you make this number at least 50 and do a little

; testing to see what's reliable in your particular situation. On Flat maps, you can probably get

; it pretty low, but you need some room for the aircraft to clear the blast.

_flyHeight = 50

; The type of aircraft providing support. Tested BIS values:

; "Su25"

; "A10"

; "A10LGB"

; "Cessna"

_acType = "A10"

; The pilot type. Tested BIS values:

; "SoldierWPilot"

; "SoldierEPilot"

; "SoldierGPilot"

; "Civilian"

_crewType = "SoldierWPilot"

; The type of missile to deploy

; There is a limitation of the OFP engine, the plane must be able to carry the related weapon (built into the game)

; in order to actually use it. The Su-25 and both A-10s use: "MaverickLauncher" as their weapon name. The magazine

; for these planes are also "MaverickLauncher" . This parameter is really only here so this script can be used

; with mods without having to modify the script. If you're going with standard clean ofp, this should always

; be "MaverickLauncher" .

; If you want to use an addon aircraft that's not documented do this:

; Create a test aircraft on a blank map with the player as the pilot.

; Put the following in the aircraft's init feild.

; hintC format["Weapons: ""%1"", Magazines: ""%2""", weapons this, magazines this]

; (credit to "xenom" as above)

; This will tell you everything the aircraft carries as soon as the test mission starts

_missileTypeWeapon = "MaverickLauncher"

; See missileTypeWeapon Above

_missileTypeMagazine = "MaverickLauncher"

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Added for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; this is the time the player won't be able to use the radio after calling the strike

hs_rto_dly = 5

; finished, the support should work now.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Added for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; takes care of Number of strikes check and RTO messages

? ((CSL_FWAS_NumberOfStrikesAvailable == 0) AND (call hs_hearRTO)) : [units _group select 0, "Negative, there are no strike aircraft on station, over."] call hs_sidechat

? (CSL_FWAS_NumberOfStrikesAvailable == 0) : exit

CSL_FWAS_NumberOfStrikesAvailable = CSL_FWAS_NumberOfStrikesAvailable - 1

? call hs_hearRTO : [units _group select 0, "Roger, setting up for attack run, over."] call hs_sidechat

; delay the script's execution the specified number of seconds

~_delayBeforeInbound

; get the designated spot

_designator = objNull

"if (typeOf _x == ""LaserTargetW"") then {_designator = _x}" forEach _unitList

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;Changed for HS Radio Support;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; if nothing is designated, abort the attack run

; ? (IsNull _designator) : units _group select 0 sideChat "We are not receiveing a signal, aborting run, over."; exit

; change: converted to HS message system

? ((IsNull _designator) AND (call hs_hearRTO)) : [units _group select 0, "We are not receiveing a signal, aborting run, over."] call hs_sidechat

? (IsNull _designator) : exit

; if something is designated, set the marker's position to the designated spot.

_attackMarker setMarkerPos [getPos _designator select 0, getPos _designator select 1]

; check that the approach and exit directions are valid. If they're not, abort the script

? _approachFrom == _exitTo : hintC "The AI performs eratically when you set the approach and exit directions to be the same. Please set them to different directions"; exit

_validApproach = false

_validExit = false

? _approachFrom == "n" : _validApproach = true

? _approachFrom == "e" : _validApproach = true

? _approachFrom == "s" : _validApproach = true

? _approachFrom == "w" : _validApproach = true

? _approachFrom == "ne" : _validApproach = true

? _approachFrom == "se" : _validApproach = true

? _approachFrom == "sw" : _validApproach = true

? _approachFrom == "nw" : _validApproach = true

? !(_validApproach) : hintC format["The Approach direction specified is invalid. Must be one of ""n"" ""e"" ""s"" ""w"" ""ne"" ""se"" ""sw"" ""nw""."]; exit

? _exitTo == "n" : _validExit = true

? _exitTo == "e" : _validExit = true

? _exitTo == "s" : _validExit = true

? _exitTo == "w" : _validExit = true

? _exitTo == "ne" : _validExit = true

? _exitTo == "se" : _validExit = true

? _exitTo == "sw" : _validExit = true

? _exitTo == "nw" : _validExit = true

? !(_validExit) : hintC format["The exit direction specified is invalid. Must be one of ""n"" ""e"" ""s"" ""w"" ""ne"" ""se"" ""sw"" ""nw""."]; exit

; spawn the plane and the pilot

_aircraft = _acType createVehicle [getPos ((units _group) select 0) select 0, getPos ((units _group) select 0) select 2, _flyHeight]

_crewType createunit [getPos ((units _group) select 0), _group, "", 1, "PRIVATE"]

; give the pilot time to spawn and show up in the _pilotList

~1

; get the pilot from the pilot list, and stick him in the cockpit.

"if (typeOf _x == _crewType) then {_x assignAsDriver _aircraft; _x moveInDriver _aircraft}" forEach (_pilotList)

_pilot = driver _aircraft

; set the strike aircraft's waypoint and flight altitude

_aircraft doMove [getMarkerPos _attackMarker select 0, getMarkerPos _attackMarker select 1, _flyHeight]

_aircraft flyInHeight _flyHeight

; set the pilot to be reckless so he doesn't try to engage other opponents

"_x setCombatMode ""BLUE""" foreach units _group

"_x setBehaviour ""CARELESS""" foreach units _group

; remove all armament from the plane to help enforce him not engaging other opponents

removeAllWeapons _aircraft

; give it some missiles to fire at the target

_aircraft addWeapon _missileTypeWeapon

_aircraft addMagazine _missileTypeMagazine