Black seagulls needed

[lonesoldier 0]

IS there ANYWHERE that i can get Black Seagulls, to use as crows.

They are badly needed. ASAP.

Thanks.

[Major Fubar 0]

Try here

[Unatomber 0]

Why dont you just use Kegetys' Spectating script

[lonesoldier 0]

Dude, i need them for a mission i'm making.

Its in a dark and gloomy setting at a graveyard, and i need crows to fly at the player to scare the shit outta him/her.

[Major Fubar 0]

You might have to retexture the ingame seagulls, but how you'd get them to fly around is bound to be more difficult.

[N.o.R.S.u 0]

Wasn't there a seagull flying in the first real mission of the Cold War Crisis campaign?

[VXR 9]

I think Klink aslo has a script that makes a few seaguls fly around a boat or something.

[-CCCP-Stalker 0]

I have the script to make seagulls fly somewhere...

[-CCCP-Stalker 0]

Oh here it is. For one seagull:

; Seagull v.1.0

; Author: Petroizki

; E-mail: -

; PARAMETERS: [OBJECT]

; EXAMPLE: [player] exec "seagull.sqs"

;---------------------------------------------------------------

;--                    GLOBAL VARIABLES                       --

;---------------------------------------------------------------

; Rectangles middle point

_g_object      = _this Select 0

; Seagull's flying altitude

_g_altitude    = 8

; Rectangles side, where seagull's are flying at

_g_rect_height = 600

_g_rect_width  = 600

_g_height_div2 = (_g_rect_height / 2)

_g_width_div2  = (_g_rect_width / 2)

; Start the seagull from the edge of rect, so player doesn't see them respawn

_g_position_x  = ((GetPos _g_object) Select 0) - _g_width_div2

_g_position_y  = ((GetPos _g_object) Select 1) - _g_height_div2

; Create the seagull's

_g_seagull    = "seagull" CamCreate [_g_position_x, _g_position_y, _g_altitude]

;                END OF GLOBAL VARIABLES                    _

;---------------------------------------------------------------

;--               SEAGULL's FLYING ALGHORITM                  --

;---------------------------------------------------------------

#Fly

~0.1

; Get player's position

_g_position_x = (GetPos _g_object) Select 0

_g_position_y = (GetPos _g_object) Select 1

; Get random place in rectangle and place it into real coordinates

_x_waypoint = (Random _g_rect_width) - _g_width_div2

_y_waypoint = (Random _g_rect_height) - _g_height_div2

_x_waypoint = _x_waypoint + _g_position_x

_y_waypoint = _y_waypoint + _g_position_y

; Get waypoint's vector, to calculate the length of trip

_wp_vector_x = (GetPos _g_seagull) Select 0

_wp_vector_y = (GetPos _g_seagull) Select 1

_wp_vector_x = _wp_vector_x - _x_waypoint

_wp_vector_y = _wp_vector_y - _y_waypoint

; Calculate the vector lenght, so we know the distance of seagull from the waypoint, and the time taken to trip

_trip_length = sqrt(_wp_vector_x*_wp_vector_x + _wp_vector_y*_wp_vector_y)

;Hint "Seagull: Flying to new position"

; Fly there my friend..

_g_seagull CamSetPos [_x_waypoint, _y_waypoint, _g_altitude]

; I assume that the seagull doesn't fly faster than 47km/h (= ~13m/s).

_time_to_trip = _trip_length / 13

~_time_to_trip

Goto "Fly"

;          END OF SEAGULL's FLYING ALGHORITM                _

For multiple seagulls:

; Seagull v.1.0

; Author: Petroizki

; E-mail: -

; PARAMETERS: [OBJECT, NUMBER_OF_BIRDS]

; EXAMPLE: [player, 100] exec "seagulls.sqs"

_TEMP   = _this select 0

_i      = _this select 1

#Loop

?_i <= 0 : Goto "Exit"

[_TEMP] exec "seagull.sqs"

_i = _i - 1

~0.1

Goto "Loop"

#Exit

exit

Both scripts should be in the mission folder

[lonesoldier 0]

THANKYOU VERY FUCKING MUCH!!!!!!!!!!!1

[Leone 1]

PM me your email address...I have seagull textures for you. It's up to you to do all the config though.