How would one enter another loop in intro.sqs after exiting another...

[Wilson_B 10]

Hey everyone. Im working on some cinematics for the campaign I am currently working on. I have the intro.sqs working like a charm, however Im encountering something which is really stumping me.

I set up the various cam angles for the dif shots, and after 3 shots it cuts to a fixed camera of the right side of helo. Once that shot is done, I successfuly exit the loop via a trigger with appropriate activation and condition and it cuts to the next camera shot. Now following this next static camera shot, after 30 seconds its supposed to cut to another camera fixed to pmc1 who is cargo in the helicopter however the second time I try to do a loop at this point it doesnt cut to the camera. Camera shot just stays at last static camera position... Here's the .sqs so far...

;Mission 4 - The Great Outdoors

;ACT 1 - SCENE 1 INTRO

;---------------------------------------------------------------------

titleText ["29.05.12 0930 ALPHA CENTRAL PROVINCE TAKISTAN", "BLACK IN"]; titleFadeOut 10;

_camera = "camera" camcreate [0,0,0]

_camera cameraeffect ["internal", "back"]

;comment "23:24:20";

_camera camPrepareTarget [-43927.74,76531.66,-51283.89];

_camera camPreparePos [1030.15,3615.05,0.90];

_camera camPrepareFOV 0.700;

_camera camCommitPrepared 0

;comment "23:22:53";

;_camera camPrepareTarget [-72602.60,-63506.05,8512.17];

_camera camPrepareTarget bell1;

_camera camPreparePos [1030.15,3615.05,0.90];

_camera camPrepareFOV 0.300;

_camera camCommitPrepared 10

@camCommitted _camera

;---------------------------------------------------------------------

;comment "23:25:25";

_camera camPrepareTarget bell1;

_camera camPreparePos [1030.15,3615.05,0.90];

_camera camPrepareFOV 0.300;

_camera camCommitPrepared 0

~16

;FIRST CAMERA LOOP FIXED TO VEHICLE (EXITS VIA TRIGGER (50000x50000) WITH TIME DELAY OF 10 10 10, CONDITION: startcount, ON ACTIVATION: endcameralock1)

;---------------------------------------------------------------------

startcount=true

#loop

_camera cameraeffect ["internal", "back"]

_camera camsettarget bell1

_camera camPrepareFOV 0.050

_camera camsetrelpos [120,0,0]

_camera camcommit 0

? (endcameralock1) : goto "nextstep"

goto "loop"

;STATIC CAMERA SHOT AFTER LOOP

;---------------------------------------------------------------------

#nextstep

;comment "2:28:50";

_camera camPrepareTarget bell1;

_camera camPreparePos [2194.01,4213.73,0.73];

_camera camPrepareFOV 0.100;

_camera camCommitPrepared 0

~20

;SCRIPT DOESNT WORK PAST THIS POINT

;---------------------------------------------------------------------

startcount2=true

#loop

_camera cameraeffect ["internal", "back"]

_camera camsettarget bell1

_camera camPrepareFOV 0.500

_camera camsetrelpos [0,1,0]

_camera camcommit 0

? (endcameralock2) : goto "nextstep2"

goto "loop"

;TEST STATIC CAMERA POSITION TO SEE IF LAST FIXED VEHICLE CAMERA LOOP EXITS TO ANOTHER SHOT

;---------------------------------------------------------------------

#nextstep2

;comment "2:28:50";

_camera camPrepareTarget bell1;

_camera camPreparePos [2194.01,4213.73,0.73];

_camera camPrepareFOV 0.100;

_camera camCommitPrepared 0

@camCommitted _camera

~30

I hope someone has some insight into what Im doing wrong...

Wilson

---------- Post added at 08:05 PM ---------- Previous post was at 07:34 PM ----------

Well I was just reading that in order to start a second looping camera I infact have to initiate it in a second intro.sqs file. Will have to see if this works.

*SOLVED* Second looping camera to be used in seperate intro script (intro2.sqs). In trigger that cuts the first looping cam I added this to init line to go to second intro script once first had ended:

endcameralock1 = true; pmc3 exec "intro2.sqs"

Edited April 19, 2011 by Wilson_B

[Clayman 20]

You are using the same label name for both loops. When the script reaches the second goto, it jumps back to the first #loop. As the condition is met it moves on to #nextstep and this repeats again and again.

Simply rename the second loop to #loop1 and goto "loop1".

[Wilson_B 10]

gotcha thanks, wasn't sure if #loop was a named command or just a name that is defined by user... makes sense now though.